Adding submodules and stuff.

sources_non_forked/syntastic/syntax_checkers/php/php.vim

@@ -0,0 +1,52 @@
+"============================================================================
+"File:        php.vim
+"Description: Syntax checking plugin for syntastic.vim
+"Maintainer:  Martin Grenfell <martin.grenfell at gmail dot com>
+"License:     This program is free software. It comes without any warranty,
+"             to the extent permitted by applicable law. You can redistribute
+"             it and/or modify it under the terms of the Do What The Fuck You
+"             Want To Public License, Version 2, as published by Sam Hocevar.
+"             See http://sam.zoy.org/wtfpl/COPYING for more details.
+"
+"============================================================================
+
+if exists("g:loaded_syntastic_php_php_checker")
+    finish
+endif
+let g:loaded_syntastic_php_php_checker=1
+
+function! SyntaxCheckers_php_php_IsAvailable()
+    return executable("php")
+endfunction
+
+function! SyntaxCheckers_php_php_GetHighlightRegex(item)
+    let unexpected = matchstr(a:item['text'], "unexpected '[^']\\+'")
+    if len(unexpected) < 1
+        return ''
+    endif
+    return '\V'.split(unexpected, "'")[1]
+endfunction
+
+function! SyntaxCheckers_php_php_GetLocList()
+    let makeprg = syntastic#makeprg#build({
+        \ 'exe': 'php',
+        \ 'args': '-l -d error_reporting=E_ALL -d display_errors=1 -d log_errors=0 -d xdebug.cli_color=0',
+        \ 'filetype': 'php',
+        \ 'subchecker': 'php' })
+
+    let errorformat =
+        \ '%-GNo syntax errors detected in%.%#,'.
+        \ 'Parse error: %#syntax %trror\, %m in %f on line %l,'.
+        \ 'Parse %trror: %m in %f on line %l,'.
+        \ 'Fatal %trror: %m in %f on line %l,'.
+        \ '%-G\s%#,'.
+        \ '%-GErrors parsing %.%#'
+
+    return SyntasticMake({
+        \ 'makeprg': makeprg,
+        \ 'errorformat': errorformat })
+endfunction
+
+call g:SyntasticRegistry.CreateAndRegisterChecker({
+    \ 'filetype': 'php',
+    \ 'name': 'php'})

sources_non_forked/syntastic/syntax_checkers/php/phpcs.vim

@@ -0,0 +1,44 @@
+"============================================================================
+"File:        phpcs.vim
+"Description: Syntax checking plugin for syntastic.vim
+"Maintainer:  Martin Grenfell <martin.grenfell at gmail dot com>
+"License:     This program is free software. It comes without any warranty,
+"             to the extent permitted by applicable law. You can redistribute
+"             it and/or modify it under the terms of the Do What The Fuck You
+"             Want To Public License, Version 2, as published by Sam Hocevar.
+"             See http://sam.zoy.org/wtfpl/COPYING for more details.
+"
+"============================================================================
+"
+" See here for details of phpcs
+"    - phpcs (see http://pear.php.net/package/PHP_CodeSniffer)
+"
+if exists("g:loaded_syntastic_php_phpcs_checker")
+    finish
+endif
+let g:loaded_syntastic_php_phpcs_checker=1
+
+function! SyntaxCheckers_php_phpcs_IsAvailable()
+    return executable('phpcs')
+endfunction
+
+function! SyntaxCheckers_php_phpcs_GetLocList()
+    let makeprg = syntastic#makeprg#build({
+        \ 'exe': 'phpcs',
+        \ 'args': '--report=csv',
+        \ 'filetype': 'php',
+        \ 'subchecker': 'phpcs' })
+
+    let errorformat =
+        \ '%-GFile\,Line\,Column\,Type\,Message\,Source\,Severity,'.
+        \ '"%f"\,%l\,%c\,%t%*[a-zA-Z]\,"%m"\,%*[a-zA-Z0-9_.-]\,%*[0-9]'
+
+    return SyntasticMake({
+        \ 'makeprg': makeprg,
+        \ 'errorformat': errorformat,
+        \ 'subtype': 'Style' })
+endfunction
+
+call g:SyntasticRegistry.CreateAndRegisterChecker({
+    \ 'filetype': 'php',
+    \ 'name': 'phpcs'})

sources_non_forked/syntastic/syntax_checkers/php/phpmd.vim

@@ -0,0 +1,78 @@
+"============================================================================
+"File:        phpmd.vim
+"Description: Syntax checking plugin for syntastic.vim
+"Maintainer:  Martin Grenfell <martin.grenfell at gmail dot com>
+"License:     This program is free software. It comes without any warranty,
+"             to the extent permitted by applicable law. You can redistribute
+"             it and/or modify it under the terms of the Do What The Fuck You
+"             Want To Public License, Version 2, as published by Sam Hocevar.
+"             See http://sam.zoy.org/wtfpl/COPYING for more details.
+"
+"============================================================================
+"
+" See here for details of phpmd
+"   - phpmd (see http://phpmd.org)
+
+if exists("g:loaded_syntastic_php_phpmd_checker")
+    finish
+endif
+let g:loaded_syntastic_php_phpmd_checker=1
+
+function! SyntaxCheckers_php_phpmd_IsAvailable()
+    return executable('phpmd')
+endfunction
+
+function! SyntaxCheckers_php_phpmd_GetHighlightRegex(item)
+    let term = matchstr(a:item['text'], '\C^The \S\+ \w\+\(()\)\= \(has\|is not\|utilizes\)')
+    if term != ''
+        return '\V'.substitute(term, '\C^The \S\+ \(\w\+\)\(()\)\= .*', '\1', '')
+    endif
+    let term = matchstr(a:item['text'], '\C^Avoid \(variables with short\|excessively long variable\) names like \S\+\.')
+    if term != ''
+        return '\V'.substitute(term, '\C^Avoid \(variables with short\|excessively long variable\) names like \(\S\+\)\..*', '\2', '')
+    endif
+    let term = matchstr(a:item['text'], '\C^Avoid using short method names like \S\+::\S\+()\.')
+    if term != ''
+        return '\V'.substitute(term, '\C^Avoid using short method names like \S\+::\(\S\+\)()\..*', '\1', '')
+    endif
+    let term = matchstr(a:item['text'], '\C^\S\+ accesses the super-global variable ')
+    if term != ''
+        return '\V'.substitute(term, '\C accesses the super-global variable .*$', '', '')
+    endif
+    let term = matchstr(a:item['text'], '\C^Constant \S\+ should be defined in uppercase')
+    if term != ''
+        return '\V'.substitute(term, '\C^Constant \(\S\+\) should be defined in uppercase', '\1', '')
+    endif
+    let term = matchstr(a:item['text'], "\\C^The '\\S\\+()' method which returns ")
+    if term != ''
+        return '\V'.substitute(term, "\\C^The '\\(\\S\\+\\()' method which returns.*", '\1', '')
+    endif
+    let term = matchstr(a:item['text'], '\C variable \S\+ should begin with ')
+    if term != ''
+        return '\V'.substitute(term, '\C.* variable \(\S\+\) should begin with .*', '\1', '')
+    endif
+    let term = matchstr(a:item['text'], "\\C^Avoid unused \\(private fields\\|local variables\\|private methods\\|parameters\\) such as '\\S\\+'")
+    if term != ''
+        return '\V'.substitute(term, "\\C^Avoid unused \\(private fields\\|local variables\\|private methods\\|parameters\\) such as '\\(\\S\\+\\)'.*", '\2', '')
+    endif
+    return ''
+endfunction
+
+function! SyntaxCheckers_php_phpmd_GetLocList()
+    let makeprg = syntastic#makeprg#build({
+        \ 'exe': 'phpmd',
+        \ 'post_args': 'text codesize,design,unusedcode,naming',
+        \ 'filetype': 'php',
+        \ 'subchecker': 'phpmd' })
+
+    let errorformat = '%E%f:%l%\s%#%m'
+
+    return SyntasticMake({
+        \ 'makeprg': makeprg,
+        \ 'errorformat': errorformat,
+        \ 'subtype' : 'Style' })
+endfunction
+
+call g:SyntasticRegistry.CreateAndRegisterChecker({
+    \ 'filetype': 'php',
+    \ 'name': 'phpmd'})