gitignore sources_non_forked_cache

sources_non_forked/ale/ale_linters/cpp/cc.vim

@@ -0,0 +1,67 @@
+" Author: w0rp <devw0rp@gmail.com>
+" Description: A C++ compiler linter for C++ files with gcc/clang, etc.
+
+call ale#Set('cpp_cc_executable', '<auto>')
+call ale#Set('cpp_cc_options', '-std=c++14 -Wall')
+call ale#Set('cpp_cc_use_header_lang_flag', -1)
+call ale#Set('cpp_cc_header_exts', ['h', 'hpp'])
+
+function! ale_linters#cpp#cc#GetExecutable(buffer) abort
+    let l:executable = ale#Var(a:buffer, 'cpp_cc_executable')
+
+    " Default to either clang++ or gcc.
+    if l:executable is# '<auto>'
+        if ale#engine#IsExecutable(a:buffer, 'clang++')
+            let l:executable = 'clang++'
+        else
+            let l:executable = 'gcc'
+        endif
+    endif
+
+    return l:executable
+endfunction
+
+function! ale_linters#cpp#cc#GetCommand(buffer, output) abort
+    let l:cflags = ale#c#GetCFlags(a:buffer, a:output)
+    let l:ale_flags = ale#Var(a:buffer, 'cpp_cc_options')
+
+    if l:cflags =~# '-std='
+        let l:ale_flags = substitute(
+        \   l:ale_flags,
+        \   '-std=\(c\|gnu\)++[0-9]\{2\}',
+        \   '',
+        \   'g')
+    endif
+
+    " Select the correct language flag depending on the executable, options
+    " and file extension
+    let l:executable = ale_linters#cpp#cc#GetExecutable(a:buffer)
+    let l:use_header_lang_flag = ale#Var(a:buffer, 'cpp_cc_use_header_lang_flag')
+    let l:header_exts = ale#Var(a:buffer, 'cpp_cc_header_exts')
+    let l:lang_flag = ale#c#GetLanguageFlag(
+    \   a:buffer,
+    \   l:executable,
+    \   l:use_header_lang_flag,
+    \   l:header_exts,
+    \   'c++')
+
+    " -iquote with the directory the file is in makes #include work for
+    "  headers in the same directory.
+    "
+    " `-o /dev/null` or `-o null` is needed to catch all errors,
+    " -fsyntax-only doesn't catch everything.
+    return '%e -S -x ' . l:lang_flag
+    \   . ' -o ' . g:ale#util#nul_file
+    \   . ' -iquote %s:h'
+    \   . ale#Pad(l:cflags)
+    \   . ale#Pad(l:ale_flags) . ' -'
+endfunction
+
+call ale#linter#Define('cpp', {
+\   'name': 'cc',
+\   'aliases': ['gcc', 'clang', 'g++', 'clang++'],
+\   'output_stream': 'stderr',
+\   'executable': function('ale_linters#cpp#cc#GetExecutable'),
+\   'command': {b -> ale#c#RunMakeCommand(b, function('ale_linters#cpp#cc#GetCommand'))},
+\   'callback': 'ale#handlers#gcc#HandleGCCFormatWithIncludes',
+\})

sources_non_forked/ale/ale_linters/cpp/ccls.vim

@@ -0,0 +1,15 @@
+" Author: Ye Jingchen <ye.jingchen@gmail.com>, Ben Falconer <ben@falconers.me.uk>, jtalowell <jtalowell@protonmail.com>
+" Description: A language server for C++
+
+call ale#Set('cpp_ccls_executable', 'ccls')
+call ale#Set('cpp_ccls_init_options', {})
+call ale#Set('c_build_dir', '')
+
+call ale#linter#Define('cpp', {
+\   'name': 'ccls',
+\   'lsp': 'stdio',
+\   'executable': {b -> ale#Var(b, 'cpp_ccls_executable')},
+\   'command': '%e',
+\   'project_root': function('ale#handlers#ccls#GetProjectRoot'),
+\   'initialization_options': {b -> ale#handlers#ccls#GetInitOpts(b, 'cpp_ccls_init_options')},
+\})

sources_non_forked/ale/ale_linters/cpp/clangcheck.vim

@@ -0,0 +1,35 @@
+" Author: gagbo <gagbobada@gmail.com>
+" Description: clang-check linter for cpp files
+
+call ale#Set('cpp_clangcheck_executable', 'clang-check')
+call ale#Set('cpp_clangcheck_options', '')
+call ale#Set('c_build_dir', '')
+
+function! ale_linters#cpp#clangcheck#GetCommand(buffer) abort
+    let l:user_options = ale#Var(a:buffer, 'cpp_clangcheck_options')
+
+    " Try to find compilation database to link automatically
+    let l:build_dir = ale#Var(a:buffer, 'c_build_dir')
+
+    if empty(l:build_dir)
+        let [l:root, l:json_file] = ale#c#FindCompileCommands(a:buffer)
+        let l:build_dir = ale#path#Dirname(l:json_file)
+    endif
+
+    " The extra arguments in the command are used to prevent .plist files from
+    " being generated. These are only added if no build directory can be
+    " detected.
+    return '%e -analyze %s'
+    \   . (empty(l:build_dir) ? ' --extra-arg=-Xclang --extra-arg=-analyzer-output=text --extra-arg=-fno-color-diagnostics': '')
+    \   . ale#Pad(l:user_options)
+    \   . (!empty(l:build_dir) ? ' -p ' . ale#Escape(l:build_dir) : '')
+endfunction
+
+call ale#linter#Define('cpp', {
+\   'name': 'clangcheck',
+\   'output_stream': 'stderr',
+\   'executable': {b -> ale#Var(b, 'cpp_clangcheck_executable')},
+\   'command': function('ale_linters#cpp#clangcheck#GetCommand'),
+\   'callback': 'ale#handlers#gcc#HandleGCCFormat',
+\   'lint_file': 1,
+\})

sources_non_forked/ale/ale_linters/cpp/clangd.vim

@@ -0,0 +1,22 @@
+" Author: Andrey Melentyev <andrey.melentyev@protonmail.com>
+" Description: Clangd language server
+
+call ale#Set('cpp_clangd_executable', 'clangd')
+call ale#Set('cpp_clangd_options', '')
+call ale#Set('c_build_dir', '')
+
+function! ale_linters#cpp#clangd#GetCommand(buffer) abort
+    let l:build_dir = ale#c#GetBuildDirectory(a:buffer)
+
+    return '%e'
+    \    . ale#Pad(ale#Var(a:buffer, 'cpp_clangd_options'))
+    \    . (!empty(l:build_dir) ? ' -compile-commands-dir=' . ale#Escape(l:build_dir) : '')
+endfunction
+
+call ale#linter#Define('cpp', {
+\   'name': 'clangd',
+\   'lsp': 'stdio',
+\   'executable': {b -> ale#Var(b, 'cpp_clangd_executable')},
+\   'command': function('ale_linters#cpp#clangd#GetCommand'),
+\   'project_root': function('ale#c#FindProjectRoot'),
+\})

sources_non_forked/ale/ale_linters/cpp/clangtidy.vim

@@ -0,0 +1,53 @@
+" Author: vdeurzen <tim@kompiler.org>, w0rp <devw0rp@gmail.com>,
+" gagbo <gagbobada@gmail.com>
+" Description: clang-tidy linter for cpp files
+
+call ale#Set('cpp_clangtidy_executable', 'clang-tidy')
+" Set this option to check the checks clang-tidy will apply.
+call ale#Set('cpp_clangtidy_checks', [])
+" Set this option to manually set some options for clang-tidy to use as compile
+" flags.
+" This will disable compile_commands.json detection.
+call ale#Set('cpp_clangtidy_options', '')
+" Set this option to manually set options for clang-tidy directly.
+call ale#Set('cpp_clangtidy_extra_options', '')
+call ale#Set('c_build_dir', '')
+
+function! ale_linters#cpp#clangtidy#GetCommand(buffer, output) abort
+    let l:checks = join(ale#Var(a:buffer, 'cpp_clangtidy_checks'), ',')
+    let l:build_dir = ale#c#GetBuildDirectory(a:buffer)
+    let l:options = ''
+
+    " Get the extra options if we couldn't find a build directory.
+    if empty(l:build_dir)
+        let l:options = ale#Var(a:buffer, 'cpp_clangtidy_options')
+        let l:cflags = ale#c#GetCFlags(a:buffer, a:output)
+        let l:options .= !empty(l:options) ? ale#Pad(l:cflags) : l:cflags
+
+        " Tell clang-tidy a .h header with a C++ filetype in Vim is a C++ file
+        " only when compile-commands.json file is not there. Adding these
+        " flags makes clang-tidy completely ignore compile commands.
+        if expand('#' . a:buffer) =~# '\.h$'
+            let l:options .= !empty(l:options) ? ' -x c++' : '-x c++'
+        endif
+    endif
+
+    " Get the options to pass directly to clang-tidy
+    let l:extra_options = ale#Var(a:buffer, 'cpp_clangtidy_extra_options')
+
+    return '%e'
+    \   . (!empty(l:checks) ? ' -checks=' . ale#Escape(l:checks) : '')
+    \   . (!empty(l:extra_options) ? ' ' . ale#Escape(l:extra_options) : '')
+    \   . ' %s'
+    \   . (!empty(l:build_dir) ? ' -p ' . ale#Escape(l:build_dir) : '')
+    \   . (!empty(l:options) ? ' -- ' . l:options : '')
+endfunction
+
+call ale#linter#Define('cpp', {
+\   'name': 'clangtidy',
+\   'output_stream': 'stdout',
+\   'executable': {b -> ale#Var(b, 'cpp_clangtidy_executable')},
+\   'command': {b -> ale#c#RunMakeCommand(b, function('ale_linters#cpp#clangtidy#GetCommand'))},
+\   'callback': 'ale#handlers#gcc#HandleGCCFormat',
+\   'lint_file': 1,
+\})

sources_non_forked/ale/ale_linters/cpp/clazy.vim

@@ -0,0 +1,32 @@
+" Description: clazy linter for cpp files (clang-based and Qt-oriented)
+
+call ale#Set('cpp_clazy_executable', 'clazy-standalone')
+" Set this option to check the checks clazy will apply.
+call ale#Set('cpp_clazy_checks', ['level1'])
+" Set this option to manually set some options for clazy.
+" This will disable compile_commands.json detection.
+call ale#Set('cpp_clazy_options', '')
+call ale#Set('c_build_dir', '')
+
+function! ale_linters#cpp#clazy#GetCommand(buffer) abort
+    let l:checks = join(ale#Var(a:buffer, 'cpp_clazy_checks'), ',')
+    let l:build_dir = ale#c#GetBuildDirectory(a:buffer)
+
+    " Get the extra options if we couldn't find a build directory.
+    let l:options = ale#Var(a:buffer, 'cpp_clazy_options')
+
+    return '%e'
+    \   . (!empty(l:checks) ? ' -checks=' . ale#Escape(l:checks) : '')
+    \   . (!empty(l:build_dir) ? ' -p ' . ale#Escape(l:build_dir) : '')
+    \   . (!empty(l:options) ? ' ' . l:options : '')
+    \   . ' %s'
+endfunction
+
+call ale#linter#Define('cpp', {
+\   'name': 'clazy',
+\   'output_stream': 'stderr',
+\   'executable': {b -> ale#Var(b, 'cpp_clazy_executable')},
+\   'command': function('ale_linters#cpp#clazy#GetCommand'),
+\   'callback': 'ale#handlers#gcc#HandleGCCFormat',
+\   'lint_file': 1,
+\})

sources_non_forked/ale/ale_linters/cpp/cppcheck.vim

@@ -0,0 +1,29 @@
+" Author: Bart Libert <bart.libert@gmail.com>
+" Description: cppcheck linter for cpp files
+
+call ale#Set('cpp_cppcheck_executable', 'cppcheck')
+call ale#Set('cpp_cppcheck_options', '--enable=style')
+
+function! ale_linters#cpp#cppcheck#GetCommand(buffer) abort
+    let l:compile_commands_option = ale#handlers#cppcheck#GetCompileCommandsOptions(a:buffer)
+    let l:buffer_path_include = empty(l:compile_commands_option)
+    \   ? ale#handlers#cppcheck#GetBufferPathIncludeOptions(a:buffer)
+    \   : ''
+    let l:template = ' --template=' . ale#Escape('{file}:{line}:{column}: {severity}:{inconclusive:inconclusive:} {message} [{id}]\\n{code}')
+
+    return '%e -q --language=c++'
+    \   . l:template
+    \   . ale#Pad(l:compile_commands_option)
+    \   . ale#Pad(ale#Var(a:buffer, 'cpp_cppcheck_options'))
+    \   . l:buffer_path_include
+    \   . ' %t'
+endfunction
+
+call ale#linter#Define('cpp', {
+\   'name': 'cppcheck',
+\   'output_stream': 'both',
+\   'executable': {b -> ale#Var(b, 'cpp_cppcheck_executable')},
+\   'cwd': function('ale#handlers#cppcheck#GetCwd'),
+\   'command': function('ale_linters#cpp#cppcheck#GetCommand'),
+\   'callback': 'ale#handlers#cppcheck#HandleCppCheckFormat',
+\})

sources_non_forked/ale/ale_linters/cpp/cpplint.vim

@@ -0,0 +1,20 @@
+" Author: Dawid Kurek https://github.com/dawikur
+" Description: cpplint for cpp files
+
+call ale#Set('cpp_cpplint_executable', 'cpplint')
+call ale#Set('cpp_cpplint_options', '')
+
+function! ale_linters#cpp#cpplint#GetCommand(buffer) abort
+    let l:options = ale#Var(a:buffer, 'cpp_cpplint_options')
+
+    return '%e' . ale#Pad(l:options) . ' %s'
+endfunction
+
+call ale#linter#Define('cpp', {
+\   'name': 'cpplint',
+\   'output_stream': 'stderr',
+\   'executable': {b -> ale#Var(b, 'cpp_cpplint_executable')},
+\   'command': function('ale_linters#cpp#cpplint#GetCommand'),
+\   'callback': 'ale#handlers#cpplint#HandleCppLintFormat',
+\   'lint_file': 1,
+\})

sources_non_forked/ale/ale_linters/cpp/cquery.vim

@@ -0,0 +1,30 @@
+" Author: Ben Falconer <ben@falconers.me.uk>
+" Description: A language server for C++
+
+call ale#Set('cpp_cquery_executable', 'cquery')
+call ale#Set('cpp_cquery_cache_directory', expand('~/.cache/cquery'))
+
+function! ale_linters#cpp#cquery#GetProjectRoot(buffer) abort
+    " Try to find cquery configuration files first.
+    let l:config = ale#path#FindNearestFile(a:buffer, '.cquery')
+
+    if !empty(l:config)
+        return fnamemodify(l:config, ':h')
+    endif
+
+    " Fall back on default project root detection.
+    return ale#c#FindProjectRoot(a:buffer)
+endfunction
+
+function! ale_linters#cpp#cquery#GetInitializationOptions(buffer) abort
+    return {'cacheDirectory': ale#Var(a:buffer, 'cpp_cquery_cache_directory')}
+endfunction
+
+call ale#linter#Define('cpp', {
+\   'name': 'cquery',
+\   'lsp': 'stdio',
+\   'executable': {b -> ale#Var(b, 'cpp_cquery_executable')},
+\   'command': '%e',
+\   'project_root': function('ale_linters#cpp#cquery#GetProjectRoot'),
+\   'initialization_options': function('ale_linters#cpp#cquery#GetInitializationOptions'),
+\})

sources_non_forked/ale/ale_linters/cpp/cspell.vim

@@ -0,0 +1,5 @@
+scriptencoding utf-8
+" Author: David Houston <houstdav000>
+" Description: cspell support for C++ files.
+
+call ale#handlers#cspell#DefineLinter('cpp')

sources_non_forked/ale/ale_linters/cpp/flawfinder.vim

@@ -0,0 +1,25 @@
+" Author: Christian Gibbons <cgibbons@gmu.edu>
+" Description: flawfinder linter for c++ files
+
+call ale#Set('cpp_flawfinder_executable', 'flawfinder')
+call ale#Set('cpp_flawfinder_options', '')
+call ale#Set('cpp_flawfinder_minlevel', 1)
+call ale#Set('c_flawfinder_error_severity', 6)
+
+function! ale_linters#cpp#flawfinder#GetCommand(buffer) abort
+    " Set the minimum vulnerability level for flawfinder to bother with
+    let l:minlevel = ' --minlevel=' . ale#Var(a:buffer, 'cpp_flawfinder_minlevel')
+
+    return '%e -CDQS'
+    \  . ale#Var(a:buffer, 'cpp_flawfinder_options')
+    \  . l:minlevel
+    \  . ' %t'
+endfunction
+
+call ale#linter#Define('cpp', {
+\  'name': 'flawfinder',
+\  'output_stream': 'stdout',
+\  'executable': {b -> ale#Var(b, 'cpp_flawfinder_executable')},
+\  'command': function('ale_linters#cpp#flawfinder#GetCommand'),
+\  'callback': 'ale#handlers#flawfinder#HandleFlawfinderFormat',
+\})