gitignore sources_non_forked_cache

sources_non_forked/ale/ale_linters/dart/analysis_server.vim

@@ -0,0 +1,29 @@
+" Author: Nelson Yeung <nelsyeung@gmail.com>
+" Description: Check Dart files with dart analysis server LSP
+
+call ale#Set('dart_analysis_server_executable', 'dart')
+
+function! ale_linters#dart#analysis_server#GetProjectRoot(buffer) abort
+    " Note: pub only looks for pubspec.yaml, there's no point in adding
+    " support for pubspec.yml
+    let l:pubspec = ale#path#FindNearestFile(a:buffer, 'pubspec.yaml')
+
+    return !empty(l:pubspec) ? fnamemodify(l:pubspec, ':h:h') : '.'
+endfunction
+
+function! ale_linters#dart#analysis_server#GetCommand(buffer) abort
+    let l:executable = ale#Var(a:buffer, 'dart_analysis_server_executable')
+    let l:dart = resolve(exepath(l:executable))
+
+    return '%e '
+    \   . fnamemodify(l:dart, ':h') . '/snapshots/analysis_server.dart.snapshot'
+    \   . ' --lsp'
+endfunction
+
+call ale#linter#Define('dart', {
+\   'name': 'analysis_server',
+\   'lsp': 'stdio',
+\   'executable': {b -> ale#Var(b, 'dart_analysis_server_executable')},
+\   'command': function('ale_linters#dart#analysis_server#GetCommand'),
+\   'project_root': function('ale_linters#dart#analysis_server#GetProjectRoot'),
+\})

sources_non_forked/ale/ale_linters/dart/dart_analyze.vim

@@ -0,0 +1,29 @@
+" Author: ghsang <gwonhyuksang@gmail.com>
+" Description: Check Dart files with dart analyze
+
+call ale#Set('dart_analyze_executable', 'dart')
+
+function! ale_linters#dart#dart_analyze#Handle(buffer, lines) abort
+    let l:pattern = '\v([a-z]+) - (.+):(\d+):(\d+) - (.+) - (.+)$'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        let [l:type, l:filename, l:lnum, l:col, l:message, l:code] = l:match[1:6]
+        call add(l:output, {
+        \   'type': l:type is# 'error' ? 'E' : l:type is# 'info' ? 'I' : 'W',
+        \   'text': l:code . ': ' . l:message,
+        \   'lnum': str2nr(l:lnum),
+        \   'col': str2nr(l:col),
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('dart', {
+\   'name': 'dart_analyze',
+\   'executable': {b -> ale#Var(b, 'dart_analyze_executable')},
+\   'command': '%e analyze --fatal-infos %s',
+\   'callback': 'ale_linters#dart#dart_analyze#Handle',
+\   'lint_file': 1,
+\})

sources_non_forked/ale/ale_linters/dart/language_server.vim

@@ -0,0 +1,20 @@
+" Author: aurieh <me@aurieh.me>
+" Description: A language server for dart
+
+call ale#Set('dart_language_server_executable', 'dart_language_server')
+
+function! ale_linters#dart#language_server#GetProjectRoot(buffer) abort
+    " Note: pub only looks for pubspec.yaml, there's no point in adding
+    " support for pubspec.yml
+    let l:pubspec = ale#path#FindNearestFile(a:buffer, 'pubspec.yaml')
+
+    return !empty(l:pubspec) ? fnamemodify(l:pubspec, ':h:h') : ''
+endfunction
+
+call ale#linter#Define('dart', {
+\   'name': 'language_server',
+\   'lsp': 'stdio',
+\   'executable': {b -> ale#Var(b, 'dart_language_server_executable')},
+\   'command': '%e',
+\   'project_root': function('ale_linters#dart#language_server#GetProjectRoot'),
+\})