gitignore sources_non_forked_cache

sources_non_forked/ale/ale_linters/elixir/credo.vim

@@ -0,0 +1,71 @@
+" Author: hauleth - https://github.com/hauleth
+
+function! ale_linters#elixir#credo#Handle(buffer, lines) abort
+    " Matches patterns line the following:
+    "
+    " lib/filename.ex:19:7: F: Pipe chain should start with a raw value.
+    let l:pattern = '\v:(\d+):?(\d+)?: (.): (.+)$'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        let l:type = l:match[3]
+        let l:text = l:match[4]
+
+        " Refactoring opportunities
+        if l:type is# 'F'
+            let l:type = 'W'
+        " Consistency
+        elseif l:type is# 'C'
+            let l:type = 'W'
+        " Software Design
+        elseif l:type is# 'D'
+            let l:type = 'I'
+        " Code Readability
+        elseif l:type is# 'R'
+            let l:type = 'I'
+        endif
+
+        call add(l:output, {
+        \   'bufnr': a:buffer,
+        \   'lnum': l:match[1] + 0,
+        \   'col': l:match[2] + 0,
+        \   'type': l:type,
+        \   'text': l:text,
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+function! ale_linters#elixir#credo#GetMode() abort
+    if get(g:, 'ale_elixir_credo_strict', 0)
+        return '--strict'
+    else
+        return 'suggest'
+    endif
+endfunction
+
+function! ale_linters#elixir#credo#GetConfigFile() abort
+    let l:config_file = get(g:, 'ale_elixir_credo_config_file', '')
+
+    if empty(l:config_file)
+        return ''
+    endif
+
+    return ' --config-file ' . l:config_file
+endfunction
+
+function! ale_linters#elixir#credo#GetCommand(buffer) abort
+    return 'mix help credo && '
+    \ . 'mix credo ' . ale_linters#elixir#credo#GetMode()
+    \ . ale_linters#elixir#credo#GetConfigFile()
+    \ . ' --format=flycheck --read-from-stdin %s'
+endfunction
+
+call ale#linter#Define('elixir', {
+\   'name': 'credo',
+\   'executable': 'mix',
+\   'cwd': function('ale#handlers#elixir#FindMixUmbrellaRoot'),
+\   'command': function('ale_linters#elixir#credo#GetCommand'),
+\   'callback': 'ale_linters#elixir#credo#Handle',
+\})

sources_non_forked/ale/ale_linters/elixir/cspell.vim

@@ -0,0 +1,5 @@
+scriptencoding utf-8
+" Author: David Houston <houstdav000>
+" Description: cspell support for Elixir files.
+
+call ale#handlers#cspell#DefineLinter('elixir')

sources_non_forked/ale/ale_linters/elixir/dialyxir.vim

@@ -0,0 +1,34 @@
+" Author: Fran C. - https://github.com/franciscoj
+" Description: Add dialyzer support for elixir through dialyxir
+" https://github.com/jeremyjh/dialyxir
+
+function! ale_linters#elixir#dialyxir#Handle(buffer, lines) abort
+    " Matches patterns line the following:
+    "
+    " lib/filename.ex:19: Function fname/1 has no local return
+    let l:pattern = '\v(.+):(\d+): (.+)$'
+    let l:output = []
+    let l:type = 'W'
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        if bufname(a:buffer) == l:match[1]
+            call add(l:output, {
+            \   'bufnr': a:buffer,
+            \   'lnum': l:match[2] + 0,
+            \   'col': 0,
+            \   'type': l:type,
+            \   'text': l:match[3],
+            \})
+        endif
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('elixir', {
+\   'name': 'dialyxir',
+\   'executable': 'mix',
+\   'cwd': function('ale#handlers#elixir#FindMixProjectRoot'),
+\   'command': 'mix help dialyzer && mix dialyzer',
+\   'callback': 'ale_linters#elixir#dialyxir#Handle',
+\})

sources_non_forked/ale/ale_linters/elixir/dogma.vim

@@ -0,0 +1,39 @@
+" Author: archseer - https://github.com/archSeer
+
+function! ale_linters#elixir#dogma#Handle(buffer, lines) abort
+    " Matches patterns line the following:
+    "
+    " lib/filename.ex:19:7: F: Pipe chain should start with a raw value.
+    let l:pattern = '\v:(\d+):?(\d+)?: (.): (.+)$'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        let l:type = l:match[3]
+        let l:text = l:match[4]
+
+        if l:type is# 'C'
+            let l:type = 'E'
+        elseif l:type is# 'R'
+            let l:type = 'W'
+        endif
+
+        call add(l:output, {
+        \   'bufnr': a:buffer,
+        \   'lnum': l:match[1] + 0,
+        \   'col': l:match[2] + 0,
+        \   'type': l:type,
+        \   'text': l:text,
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('elixir', {
+\   'name': 'dogma',
+\   'executable': 'mix',
+\   'cwd': function('ale#handlers#elixir#FindMixProjectRoot'),
+\   'command': 'mix help dogma && mix dogma %s --format=flycheck',
+\   'lint_file': 1,
+\   'callback': 'ale_linters#elixir#dogma#Handle',
+\})

sources_non_forked/ale/ale_linters/elixir/elixir_ls.vim

@@ -0,0 +1,21 @@
+" Author: Jon Parise <jon@indelible.org>
+" Description: ElixirLS integration (https://github.com/JakeBecker/elixir-ls)
+
+call ale#Set('elixir_elixir_ls_release', 'elixir-ls')
+call ale#Set('elixir_elixir_ls_config', {})
+
+function! ale_linters#elixir#elixir_ls#GetExecutable(buffer) abort
+    let l:dir = ale#path#Simplify(ale#Var(a:buffer, 'elixir_elixir_ls_release'))
+    let l:cmd = has('win32') ? '\language_server.bat' : '/language_server.sh'
+
+    return l:dir . l:cmd
+endfunction
+
+call ale#linter#Define('elixir', {
+\   'name': 'elixir-ls',
+\   'lsp': 'stdio',
+\   'executable': function('ale_linters#elixir#elixir_ls#GetExecutable'),
+\   'command': function('ale_linters#elixir#elixir_ls#GetExecutable'),
+\   'project_root': function('ale#handlers#elixir#FindMixUmbrellaRoot'),
+\   'lsp_config': {b -> ale#Var(b, 'elixir_elixir_ls_config')},
+\})

sources_non_forked/ale/ale_linters/elixir/mix.vim

@@ -0,0 +1,45 @@
+" Author: evnu - https://github.com/evnu
+" Author: colbydehart - https://github.com/colbydehart
+" Description: Mix compile checking for Elixir files
+
+function! ale_linters#elixir#mix#Handle(buffer, lines) abort
+    " Matches patterns like the following:
+    "
+    " Error format
+    " ** (CompileError) apps/sim/lib/sim/server.ex:87: undefined function update_in/4
+    "
+    " TODO: Warning format
+    " warning: variable "foobar" does not exist and is being expanded to "foobar()", please use parentheses to remove the ambiguity or change the variable name
+    let l:pattern = '\v\(([^\)]+Error)\) ([^:]+):([^:]+): (.+)$'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        let l:type = 'E'
+        let l:text = l:match[4]
+
+        call add(l:output, {
+        \   'bufnr': a:buffer,
+        \   'lnum': l:match[3] + 0,
+        \   'col': 0,
+        \   'type': l:type,
+        \   'text': l:text,
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+function! ale_linters#elixir#mix#GetCommand(buffer) abort
+    let l:temp_dir = ale#command#CreateDirectory(a:buffer)
+
+    return ale#Env('MIX_BUILD_PATH', l:temp_dir) . 'mix compile %s'
+endfunction
+
+call ale#linter#Define('elixir', {
+\   'name': 'mix',
+\   'executable': 'mix',
+\   'cwd': function('ale#handlers#elixir#FindMixProjectRoot'),
+\   'command': function('ale_linters#elixir#mix#GetCommand'),
+\   'callback': 'ale_linters#elixir#mix#Handle',
+\   'lint_file': 1,
+\})