gitignore sources_non_forked_cache

sources_non_forked/ale/ale_linters/go/bingo.vim

@@ -0,0 +1,31 @@
+" Author: Jerko Steiner <https://github.com/jeremija>
+" Description: https://github.com/saibing/bingo
+
+call ale#Set('go_bingo_executable', 'bingo')
+call ale#Set('go_bingo_options', '--mode stdio')
+
+function! ale_linters#go#bingo#GetCommand(buffer) abort
+    return ale#go#EnvString(a:buffer) . '%e' . ale#Pad(ale#Var(a:buffer, 'go_bingo_options'))
+endfunction
+
+function! ale_linters#go#bingo#FindProjectRoot(buffer) abort
+    let l:go_modules_off = ale#Var(a:buffer, 'go_go111module') is# 'off'
+    let l:project_root = l:go_modules_off ?
+    \ '' : ale#path#FindNearestFile(a:buffer, 'go.mod')
+    let l:mods = ':h'
+
+    if empty(l:project_root)
+        let l:project_root = ale#path#FindNearestDirectory(a:buffer, '.git')
+        let l:mods = ':h:h'
+    endif
+
+    return !empty(l:project_root) ? fnamemodify(l:project_root, l:mods) : ''
+endfunction
+
+call ale#linter#Define('go', {
+\   'name': 'bingo',
+\   'lsp': 'stdio',
+\   'executable': {b -> ale#Var(b, 'go_bingo_executable')},
+\   'command': function('ale_linters#go#bingo#GetCommand'),
+\   'project_root': function('ale_linters#go#bingo#FindProjectRoot'),
+\})

sources_non_forked/ale/ale_linters/go/cspell.vim

@@ -0,0 +1,5 @@
+scriptencoding utf-8
+" Author: David Houston <houstdav000>
+" Description: cspell support for Go files.
+
+call ale#handlers#cspell#DefineLinter('go')

sources_non_forked/ale/ale_linters/go/gobuild.vim

@@ -0,0 +1,57 @@
+" Author: Joshua Rubin <joshua@rubixconsulting.com>, Ben Reedy <https://github.com/breed808>,
+" Jeff Willette <jrwillette88@gmail.com>
+" Description: go build for Go files
+" inspired by work from dzhou121 <dzhou121@gmail.com>
+
+call ale#Set('go_go_executable', 'go')
+call ale#Set('go_gobuild_options', '')
+
+function! ale_linters#go#gobuild#GetCommand(buffer) abort
+    let l:options = ale#Var(a:buffer, 'go_gobuild_options')
+
+    " Run go test in local directory with relative path
+    return ale#go#EnvString(a:buffer)
+    \   . ale#Var(a:buffer, 'go_go_executable') . ' test'
+    \   . (!empty(l:options) ? ' ' . l:options : '')
+    \   . ' -c -o /dev/null ./'
+endfunction
+
+function! ale_linters#go#gobuild#GetMatches(lines) abort
+    " Matches patterns like the following:
+    "
+    " file.go:27: missing argument for Printf("%s"): format reads arg 2, have only 1 args
+    " file.go:53:10: if block ends with a return statement, so drop this else and outdent its block (move short variable declaration to its own line if necessary)
+    " file.go:5:2: expected declaration, found 'STRING' "log"
+    " go test returns relative paths so use tail of filename as part of pattern matcher
+    let l:pattern = '\v^([a-zA-Z]?:?[^:]+):(\d+):?(\d+)?:? (.+)$'
+
+    return ale#util#GetMatches(a:lines, l:pattern)
+endfunction
+
+function! ale_linters#go#gobuild#Handler(buffer, lines) abort
+    let l:dir = expand('#' . a:buffer . ':p:h')
+    let l:output = []
+
+    for l:match in ale_linters#go#gobuild#GetMatches(a:lines)
+        call add(l:output, {
+        \   'filename': ale#path#GetAbsPath(l:dir, l:match[1]),
+        \   'lnum': l:match[2] + 0,
+        \   'col': l:match[3] + 0,
+        \   'text': l:match[4],
+        \   'type': 'E',
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('go', {
+\   'name': 'gobuild',
+\   'aliases': ['go build'],
+\   'executable': {b -> ale#Var(b, 'go_go_executable')},
+\   'cwd': '%s:h',
+\   'command': function('ale_linters#go#gobuild#GetCommand'),
+\   'output_stream': 'stderr',
+\   'callback': 'ale_linters#go#gobuild#Handler',
+\   'lint_file': 1,
+\})

sources_non_forked/ale/ale_linters/go/gofmt.vim

@@ -0,0 +1,15 @@
+" Author: neersighted <bjorn@neersighted.com>
+" Description: gofmt for Go files
+
+function! ale_linters#go#gofmt#GetCommand(buffer) abort
+    return ale#go#EnvString(a:buffer)
+    \   . '%e -e %t'
+endfunction
+
+call ale#linter#Define('go', {
+\   'name': 'gofmt',
+\   'output_stream': 'stderr',
+\   'executable': 'gofmt',
+\   'command': function('ale_linters#go#gofmt#GetCommand'),
+\   'callback': 'ale#handlers#unix#HandleAsError',
+\})

sources_non_forked/ale/ale_linters/go/golangci_lint.vim

@@ -0,0 +1,64 @@
+" Author: Sascha Grunert <mail@saschagrunert.de>
+" Description: Adds support of golangci-lint
+
+call ale#Set('go_golangci_lint_options', '--enable-all')
+call ale#Set('go_golangci_lint_executable', 'golangci-lint')
+call ale#Set('go_golangci_lint_package', 0)
+
+function! ale_linters#go#golangci_lint#GetCommand(buffer) abort
+    let l:filename = expand('#' . a:buffer . ':t')
+    let l:options = ale#Var(a:buffer, 'go_golangci_lint_options')
+    let l:lint_package = ale#Var(a:buffer, 'go_golangci_lint_package')
+
+
+    if l:lint_package
+        return ale#go#EnvString(a:buffer)
+        \   . '%e run '
+        \   .  l:options
+    endif
+
+    return ale#go#EnvString(a:buffer)
+    \   . '%e run '
+    \   . ale#Escape(l:filename)
+    \   . ' ' . l:options
+endfunction
+
+function! ale_linters#go#golangci_lint#GetMatches(lines) abort
+    let l:pattern = '\v^([a-zA-Z]?:?[^:]+):(\d+):?(\d+)?:?:?:?\s\*?(.+)\s+\((.+)\)$'
+
+    return ale#util#GetMatches(a:lines, l:pattern)
+endfunction
+
+function! ale_linters#go#golangci_lint#Handler(buffer, lines) abort
+    let l:dir = expand('#' . a:buffer . ':p:h')
+    let l:output = []
+
+    for l:match in ale_linters#go#golangci_lint#GetMatches(a:lines)
+        if l:match[5] is# 'typecheck'
+            let l:msg_type = 'E'
+        else
+            let l:msg_type = 'W'
+        endif
+
+        " l:match[1] will already be an absolute path, output from
+        " golangci_lint
+        call add(l:output, {
+        \   'filename': ale#path#GetAbsPath(l:dir, l:match[1]),
+        \   'lnum': l:match[2] + 0,
+        \   'col': l:match[3] + 0,
+        \   'type': l:msg_type,
+        \   'text': l:match[4] . ' (' . l:match[5] . ')',
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('go', {
+\   'name': 'golangci-lint',
+\   'executable': {b -> ale#Var(b, 'go_golangci_lint_executable')},
+\   'cwd': '%s:h',
+\   'command': function('ale_linters#go#golangci_lint#GetCommand'),
+\   'callback': 'ale_linters#go#golangci_lint#Handler',
+\   'lint_file': 1,
+\})

sources_non_forked/ale/ale_linters/go/golint.vim

@@ -0,0 +1,21 @@
+" Author: neersighted <bjorn@neersighted.com>
+" Description: golint for Go files
+
+call ale#Set('go_golint_executable', 'golint')
+call ale#Set('go_golint_options', '')
+
+function! ale_linters#go#golint#GetCommand(buffer) abort
+    let l:options = ale#Var(a:buffer, 'go_golint_options')
+
+    return ale#go#EnvString(a:buffer) . '%e'
+    \   . (!empty(l:options) ? ' ' . l:options : '')
+    \   . ' %t'
+endfunction
+
+call ale#linter#Define('go', {
+\   'name': 'golint',
+\   'output_stream': 'both',
+\   'executable': {b -> ale#Var(b, 'go_golint_executable')},
+\   'command': function('ale_linters#go#golint#GetCommand'),
+\   'callback': 'ale#handlers#unix#HandleAsWarning',
+\})

sources_non_forked/ale/ale_linters/go/gometalinter.vim

@@ -0,0 +1,58 @@
+" Author: Ben Reedy <https://github.com/breed808>, Jeff Willette <jrwillette88@gmail.com>
+" Description: Adds support for the gometalinter suite for Go files
+
+call ale#Set('go_gometalinter_options', '')
+call ale#Set('go_gometalinter_executable', 'gometalinter')
+call ale#Set('go_gometalinter_lint_package', 0)
+
+function! ale_linters#go#gometalinter#GetCommand(buffer) abort
+    let l:filename = expand('#' . a:buffer . ':t')
+    let l:options = ale#Var(a:buffer, 'go_gometalinter_options')
+    let l:lint_package = ale#Var(a:buffer, 'go_gometalinter_lint_package')
+
+    " BufferCdString is used so that we can be sure the paths output from gometalinter can
+    " be calculated to absolute paths in the Handler
+    if l:lint_package
+        return ale#go#EnvString(a:buffer)
+        \   . '%e'
+        \   . (!empty(l:options) ? ' ' . l:options : '') . ' .'
+    endif
+
+    return ale#go#EnvString(a:buffer)
+    \   . '%e'
+    \   . ' --include=' . ale#Escape(ale#util#EscapePCRE(l:filename))
+    \   . (!empty(l:options) ? ' ' . l:options : '') . ' .'
+endfunction
+
+function! ale_linters#go#gometalinter#GetMatches(lines) abort
+    let l:pattern = '\v^([a-zA-Z]?:?[^:]+):(\d+):?(\d+)?:?:?(warning|error):?\s\*?(.+)$'
+
+    return ale#util#GetMatches(a:lines, l:pattern)
+endfunction
+
+function! ale_linters#go#gometalinter#Handler(buffer, lines) abort
+    let l:dir = expand('#' . a:buffer . ':p:h')
+    let l:output = []
+
+    for l:match in ale_linters#go#gometalinter#GetMatches(a:lines)
+        " l:match[1] will already be an absolute path, output from gometalinter
+        call add(l:output, {
+        \   'filename': ale#path#GetAbsPath(l:dir, l:match[1]),
+        \   'lnum': l:match[2] + 0,
+        \   'col': l:match[3] + 0,
+        \   'type': tolower(l:match[4]) is# 'warning' ? 'W' : 'E',
+        \   'text': l:match[5],
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('go', {
+\   'name': 'gometalinter',
+\   'executable': {b -> ale#Var(b, 'go_gometalinter_executable')},
+\   'cwd': '%s:h',
+\   'command': function('ale_linters#go#gometalinter#GetCommand'),
+\   'callback': 'ale_linters#go#gometalinter#Handler',
+\   'lint_file': 1,
+\})

sources_non_forked/ale/ale_linters/go/gopls.vim

@@ -0,0 +1,39 @@
+" Author: w0rp <devw0rp@gmail.com>
+" Author: Jerko Steiner <https://github.com/jeremija>
+" Description: https://github.com/saibing/gopls
+
+call ale#Set('go_gopls_executable', 'gopls')
+call ale#Set('go_gopls_options', '--mode stdio')
+call ale#Set('go_gopls_init_options', {})
+call ale#Set('go_gopls_use_global', get(g:, 'ale_use_global_executables', 0))
+
+function! ale_linters#go#gopls#GetCommand(buffer) abort
+    return ale#go#EnvString(a:buffer)
+    \   . '%e'
+    \   . ale#Pad(ale#Var(a:buffer, 'go_gopls_options'))
+endfunction
+
+function! ale_linters#go#gopls#FindProjectRoot(buffer) abort
+    let l:go_modules_off = ale#Var(a:buffer, 'go_go111module') is# 'off'
+    let l:project_root = l:go_modules_off ?
+    \ '' : ale#path#FindNearestFile(a:buffer, 'go.mod')
+    let l:mods = ':h'
+
+    if empty(l:project_root)
+        let l:project_root = ale#path#FindNearestDirectory(a:buffer, '.git')
+        let l:mods = ':h:h'
+    endif
+
+    return !empty(l:project_root) ? fnamemodify(l:project_root, l:mods) : ''
+endfunction
+
+call ale#linter#Define('go', {
+\   'name': 'gopls',
+\   'lsp': 'stdio',
+\   'executable': {b -> ale#path#FindExecutable(b, 'go_gopls', [
+\       ale#go#GetGoPathExecutable('bin/gopls'),
+\   ])},
+\   'command': function('ale_linters#go#gopls#GetCommand'),
+\   'project_root': function('ale_linters#go#gopls#FindProjectRoot'),
+\   'initialization_options': {b -> ale#Var(b, 'go_gopls_init_options')},
+\})

sources_non_forked/ale/ale_linters/go/gosimple.vim

@@ -0,0 +1,12 @@
+" Author: Ben Reedy <https://github.com/breed808>
+" Description: gosimple for Go files
+
+call ale#linter#Define('go', {
+\   'name': 'gosimple',
+\   'executable': 'gosimple',
+\   'cwd': '%s:h',
+\   'command': {b -> ale#go#EnvString(b) . 'gosimple .'},
+\   'callback': 'ale#handlers#go#Handler',
+\   'output_stream': 'both',
+\   'lint_file': 1,
+\})

sources_non_forked/ale/ale_linters/go/gotype.vim

@@ -0,0 +1,24 @@
+" Author: Jelte Fennema <github-public@jeltef.nl>
+" Description: gotype for Go files
+
+function! ale_linters#go#gotype#GetExecutable(buffer) abort
+    if expand('#' . a:buffer . ':p') =~# '_test\.go$'
+        return ''
+    endif
+
+    return 'gotype'
+endfunction
+
+function! ale_linters#go#gotype#GetCommand(buffer) abort
+    return ale#go#EnvString(a:buffer) . 'gotype -e .'
+endfunction
+
+call ale#linter#Define('go', {
+\   'name': 'gotype',
+\   'output_stream': 'stderr',
+\   'executable': function('ale_linters#go#gotype#GetExecutable'),
+\   'cwd': '%s:h',
+\   'command': function('ale_linters#go#gotype#GetCommand'),
+\   'callback': 'ale#handlers#go#Handler',
+\   'lint_file': 1,
+\})

sources_non_forked/ale/ale_linters/go/govet.vim

@@ -0,0 +1,28 @@
+" Author: neersighted <bjorn@neersighted.com>
+" Description: go vet for Go files
+"
+" Author: John Eikenberry <jae@zhar.net>
+" Description: updated to work with go1.10
+
+call ale#Set('go_go_executable', 'go')
+call ale#Set('go_govet_options', '')
+
+function! ale_linters#go#govet#GetCommand(buffer) abort
+    let l:options = ale#Var(a:buffer, 'go_govet_options')
+
+    return ale#go#EnvString(a:buffer)
+    \   . ale#Var(a:buffer, 'go_go_executable') . ' vet '
+    \   . (!empty(l:options) ? ' ' . l:options : '')
+    \   . ' .'
+endfunction
+
+call ale#linter#Define('go', {
+\   'name': 'govet',
+\   'aliases': ['go vet'],
+\   'output_stream': 'stderr',
+\   'executable': {b -> ale#Var(b, 'go_go_executable')},
+\   'cwd': '%s:h',
+\   'command': function('ale_linters#go#govet#GetCommand'),
+\   'callback': 'ale#handlers#go#Handler',
+\   'lint_file': 1,
+\})

sources_non_forked/ale/ale_linters/go/langserver.vim

@@ -0,0 +1,29 @@
+" Author: Horacio Sanson <https://github.com/hsanson>
+" Description: Support for go-langserver https://github.com/sourcegraph/go-langserver
+
+call ale#Set('go_langserver_executable', 'go-langserver')
+call ale#Set('go_langserver_options', '')
+
+function! ale_linters#go#langserver#GetCommand(buffer) abort
+    let l:executable = [ale#Escape(ale#Var(a:buffer, 'go_langserver_executable'))]
+    let l:options = ale#Var(a:buffer, 'go_langserver_options')
+    let l:options = substitute(l:options, '-gocodecompletion', '', 'g')
+    let l:options = filter(split(l:options, ' '), 'empty(v:val) != 1')
+
+    if ale#Var(a:buffer, 'completion_enabled')
+        call add(l:options, '-gocodecompletion')
+    endif
+
+    let l:options = uniq(sort(l:options))
+    let l:env = ale#go#EnvString(a:buffer)
+
+    return l:env . join(extend(l:executable, l:options), ' ')
+endfunction
+
+call ale#linter#Define('go', {
+\   'name': 'golangserver',
+\   'lsp': 'stdio',
+\   'executable': {b -> ale#Var(b, 'go_langserver_executable')},
+\   'command': function('ale_linters#go#langserver#GetCommand'),
+\   'project_root': function('ale#go#FindProjectRoot'),
+\})

sources_non_forked/ale/ale_linters/go/revive.vim

@@ -0,0 +1,21 @@
+" Author: Penghui Liao <liaoishere@gmail.com>
+" Description: Adds support for revive
+
+call ale#Set('go_revive_executable', 'revive')
+call ale#Set('go_revive_options', '')
+
+function! ale_linters#go#revive#GetCommand(buffer) abort
+    let l:options = ale#Var(a:buffer, 'go_revive_options')
+
+    return ale#go#EnvString(a:buffer) . '%e'
+    \   . (!empty(l:options) ? ' ' . l:options : '')
+    \   . ' %t'
+endfunction
+
+call ale#linter#Define('go', {
+\   'name': 'revive',
+\   'output_stream': 'both',
+\   'executable': {b -> ale#Var(b, 'go_revive_executable')},
+\   'command': function('ale_linters#go#revive#GetCommand'),
+\   'callback': 'ale#handlers#unix#HandleAsWarning',
+\})

sources_non_forked/ale/ale_linters/go/staticcheck.vim

@@ -0,0 +1,34 @@
+" Author: Ben Reedy <https://github.com/breed808>
+" Description: staticcheck for Go files
+
+call ale#Set('go_staticcheck_executable', 'staticcheck')
+call ale#Set('go_staticcheck_options', '')
+call ale#Set('go_staticcheck_lint_package', 1)
+call ale#Set('go_staticcheck_use_global', get(g:, 'ale_use_global_executables', 0))
+
+function! ale_linters#go#staticcheck#GetCommand(buffer) abort
+    let l:options = ale#Var(a:buffer, 'go_staticcheck_options')
+    let l:lint_package = ale#Var(a:buffer, 'go_staticcheck_lint_package')
+    let l:env = ale#go#EnvString(a:buffer)
+
+    if l:lint_package
+        return l:env . '%e'
+        \   . (!empty(l:options) ? ' ' . l:options : '') . ' .'
+    endif
+
+    return l:env . '%e'
+    \   . (!empty(l:options) ? ' ' . l:options : '')
+    \   . ' %s:t'
+endfunction
+
+call ale#linter#Define('go', {
+\   'name': 'staticcheck',
+\   'executable': {b -> ale#path#FindExecutable(b, 'go_staticcheck', [
+\       ale#go#GetGoPathExecutable('bin/staticcheck'),
+\   ])},
+\   'cwd': '%s:h',
+\   'command': function('ale_linters#go#staticcheck#GetCommand'),
+\   'callback': 'ale#handlers#go#Handler',
+\   'output_stream': 'both',
+\   'lint_file': 1,
+\})