gitignore sources_non_forked_cache

sources_non_forked/ale/ale_linters/json/cspell.vim

@@ -0,0 +1,5 @@
+scriptencoding utf-8
+" Author: David Houston <houstdav000>
+" Description: cspell support for JSON files.
+
+call ale#handlers#cspell#DefineLinter('json')

sources_non_forked/ale/ale_linters/json/eslint.vim

@@ -0,0 +1,16 @@
+" Author: João Pesce <joao@pesce.cc>
+" Description: eslint for JSON files.
+"
+" Requires eslint-plugin-jsonc or a similar plugin to work
+"
+" Uses the same funtcions as ale_linters/javascript/eslint.vim by w0rp
+" <devw0rp@gmail.com>
+
+call ale#linter#Define('json', {
+\   'name': 'eslint',
+\   'output_stream': 'both',
+\   'executable': function('ale#handlers#eslint#GetExecutable'),
+\   'cwd': function('ale#handlers#eslint#GetCwd'),
+\   'command': function('ale#handlers#eslint#GetCommand'),
+\   'callback': 'ale#handlers#eslint#HandleJSON',
+\})

sources_non_forked/ale/ale_linters/json/jq.vim

@@ -0,0 +1,24 @@
+" Author: jD91mZM2 <me@krake.one>
+call ale#Set('json_jq_executable', 'jq')
+call ale#Set('json_jq_options', '')
+call ale#Set('json_jq_filters', '.')
+
+" Matches patterns like the following:
+" parse error: Expected another key-value pair at line 4, column 3
+let s:pattern = '^parse error: \(.\+\) at line \(\d\+\), column \(\d\+\)$'
+
+function! ale_linters#json#jq#Handle(buffer, lines) abort
+    return ale#util#MapMatches(a:lines, s:pattern, {match -> {
+    \   'text': match[1],
+    \   'lnum': match[2] + 0,
+    \   'col': match[3] + 0,
+    \}})
+endfunction
+
+call ale#linter#Define('json', {
+\   'name': 'jq',
+\   'executable': {b -> ale#Var(b, 'json_jq_executable')},
+\   'output_stream': 'stderr',
+\   'command': '%e',
+\   'callback': 'ale_linters#json#jq#Handle',
+\})

sources_non_forked/ale/ale_linters/json/jsonlint.vim

@@ -0,0 +1,43 @@
+" Author: KabbAmine <amine.kabb@gmail.com>, David Sierra <https://github.com/davidsierradz>
+
+call ale#Set('json_jsonlint_executable', 'jsonlint')
+call ale#Set('json_jsonlint_use_global', get(g:, 'ale_use_global_executables', 0))
+
+function! ale_linters#json#jsonlint#GetExecutable(buffer) abort
+    return ale#path#FindExecutable(a:buffer, 'json_jsonlint', [
+    \   'node_modules/.bin/jsonlint',
+    \   'node_modules/jsonlint/lib/cli.js',
+    \])
+endfunction
+
+function! ale_linters#json#jsonlint#GetCommand(buffer) abort
+    let l:executable = ale_linters#json#jsonlint#GetExecutable(a:buffer)
+
+    return ale#node#Executable(a:buffer, l:executable)
+    \   . ' --compact -'
+endfunction
+
+function! ale_linters#json#jsonlint#Handle(buffer, lines) abort
+    " Matches patterns like the following:
+    " line 2, col 15, found: 'STRING' - expected: 'EOF', '}', ',', ']'.
+    let l:pattern = '^line \(\d\+\), col \(\d*\), \(.\+\)$'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        call add(l:output, {
+        \   'lnum': l:match[1] + 0,
+        \   'col': l:match[2] + 0,
+        \   'text': l:match[3],
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('json', {
+\   'name': 'jsonlint',
+\   'executable': function('ale_linters#json#jsonlint#GetExecutable'),
+\   'output_stream': 'stderr',
+\   'command': function('ale_linters#json#jsonlint#GetCommand'),
+\   'callback': 'ale_linters#json#jsonlint#Handle',
+\})

sources_non_forked/ale/ale_linters/json/spectral.vim

@@ -0,0 +1,14 @@
+" Author: t2h5 <https://github.com/t2h5>
+" Description: Integration of Stoplight Spectral CLI with ALE.
+
+call ale#Set('json_spectral_executable', 'spectral')
+call ale#Set('json_spectral_use_global', get(g:, 'ale_use_global_executables', 0))
+
+call ale#linter#Define('json', {
+\   'name': 'spectral',
+\   'executable': {b -> ale#path#FindExecutable(b, 'json_spectral', [
+\       'node_modules/.bin/spectral',
+\   ])},
+\   'command': '%e lint --ignore-unknown-format -q -f text %t',
+\   'callback': 'ale#handlers#spectral#HandleSpectralOutput'
+\})

sources_non_forked/ale/ale_linters/json/vscodejson.vim

@@ -0,0 +1,16 @@
+" Author: Dalius Dobravolskas <dalius.dobravolskas@gmail.com>
+" Description: VSCode json language server
+
+function! ale_linters#json#vscodejson#GetProjectRoot(buffer) abort
+    let l:git_path = ale#path#FindNearestDirectory(a:buffer, '.git')
+
+    return !empty(l:git_path) ? fnamemodify(l:git_path, ':h:h') : ''
+endfunction
+
+call ale#linter#Define('json', {
+\   'name': 'vscodejson',
+\   'lsp': 'stdio',
+\   'executable': 'vscode-json-language-server',
+\   'command': '%e --stdio',
+\   'project_root': function('ale_linters#json#vscodejson#GetProjectRoot'),
+\})