gitignore sources_non_forked_cache

sources_non_forked/ale/ale_linters/less/lessc.vim

@@ -0,0 +1,47 @@
+" Author: zanona <https://github.com/zanona>, w0rp <devw0rp@gmail.com>
+" Description: This file adds support for checking Less code with lessc.
+
+call ale#Set('less_lessc_executable', 'lessc')
+call ale#Set('less_lessc_options', '')
+call ale#Set('less_lessc_use_global', get(g:, 'ale_use_global_executables', 0))
+
+function! ale_linters#less#lessc#GetCommand(buffer) abort
+    return '%e --no-color --lint'
+    \   . ' --include-path=' . ale#Escape(expand('#' . a:buffer . ':p:h'))
+    \   . ale#Pad(ale#Var(a:buffer, 'less_lessc_options'))
+    \   . ' -'
+endfunction
+
+function! ale_linters#less#lessc#Handle(buffer, lines) abort
+    let l:dir = expand('#' . a:buffer . ':p:h')
+    " Matches patterns like the following:
+    let l:pattern = '^\(\w\+\): \(.\{-}\) in \(.\{-}\) on line \(\d\+\), column \(\d\+\):$'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        let l:item = {
+        \   'lnum': l:match[4] + 0,
+        \   'col': l:match[5] + 0,
+        \   'text': l:match[2],
+        \   'type': 'E',
+        \}
+
+        if l:match[3] isnot# '-'
+            let l:item.filename = ale#path#GetAbsPath(l:dir, l:match[3])
+        endif
+
+        call add(l:output, l:item)
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('less', {
+\   'name': 'lessc',
+\   'executable': {b -> ale#path#FindExecutable(b, 'less_lessc', [
+\       'node_modules/.bin/lessc',
+\   ])},
+\   'command': function('ale_linters#less#lessc#GetCommand'),
+\   'callback': 'ale_linters#less#lessc#Handle',
+\   'output_stream': 'stderr',
+\})

sources_non_forked/ale/ale_linters/less/stylelint.vim

@@ -0,0 +1,20 @@
+" Author: diartyz <diartyz@gmail.com>, w0rp <devw0rp@gmail.com>
+
+call ale#Set('less_stylelint_executable', 'stylelint')
+call ale#Set('less_stylelint_options', '')
+call ale#Set('less_stylelint_use_global', get(g:, 'ale_use_global_executables', 0))
+
+function! ale_linters#less#stylelint#GetCommand(buffer) abort
+    let l:options = ale#Var(a:buffer, 'less_stylelint_options')
+
+    return '%e' . ale#Pad(l:options) . ' --stdin-filename %s'
+endfunction
+
+call ale#linter#Define('less', {
+\   'name': 'stylelint',
+\   'executable': {b -> ale#path#FindExecutable(b, 'less_stylelint', [
+\       'node_modules/.bin/stylelint',
+\   ])},
+\   'command': function('ale_linters#less#stylelint#GetCommand'),
+\   'callback': 'ale#handlers#css#HandleStyleLintFormat',
+\})