gitignore sources_non_forked_cache

sources_non_forked/ale/ale_linters/markdown/alex.vim

@@ -0,0 +1,4 @@
+" Author: Johannes Wienke <languitar@semipol.de>
+" Description: alex for markdown files
+
+call ale#handlers#alex#DefineLinter('markdown', '')

sources_non_forked/ale/ale_linters/markdown/cspell.vim

@@ -0,0 +1,5 @@
+scriptencoding utf-8
+" Author: David Houston <houstdav000>
+" Description: cspell support for Markdown files.
+
+call ale#handlers#cspell#DefineLinter('markdown')

sources_non_forked/ale/ale_linters/markdown/languagetool.vim

@@ -0,0 +1,5 @@
+" Author: Vincent (wahrwolf [at] wolfpit.net)
+" Description: languagetool for markdown files
+
+
+call ale#handlers#languagetool#DefineLinter('markdown')

sources_non_forked/ale/ale_linters/markdown/markdownlint.vim

@@ -0,0 +1,22 @@
+" Author: Ty-Lucas Kelley <tylucaskelley@gmail.com>
+" Description: Adds support for markdownlint
+
+call ale#Set('markdown_markdownlint_options', '')
+
+function! ale_linters#markdown#markdownlint#GetCommand(buffer) abort
+    let l:executable = 'markdownlint'
+
+    let l:options = ale#Var(a:buffer, 'markdown_markdownlint_options')
+
+    return ale#Escape(l:executable)
+    \ . (!empty(l:options) ? ' ' . l:options : '') . ' %s'
+endfunction
+
+call ale#linter#Define('markdown', {
+\   'name': 'markdownlint',
+\   'executable': 'markdownlint',
+\   'lint_file': 1,
+\   'output_stream': 'both',
+\   'command': function('ale_linters#markdown#markdownlint#GetCommand'),
+\   'callback': 'ale#handlers#markdownlint#Handle'
+\})

sources_non_forked/ale/ale_linters/markdown/mdl.vim

@@ -0,0 +1,43 @@
+" Author: Steve Dignam <steve@dignam.xyz>, Josh Leeb-du Toit <joshleeb.com>
+" Description: Support for mdl, a markdown linter.
+
+call ale#Set('markdown_mdl_executable', 'mdl')
+call ale#Set('markdown_mdl_options', '')
+
+function! ale_linters#markdown#mdl#GetExecutable(buffer) abort
+    return ale#Var(a:buffer, 'markdown_mdl_executable')
+endfunction
+
+function! ale_linters#markdown#mdl#GetCommand(buffer) abort
+    let l:executable = ale_linters#markdown#mdl#GetExecutable(a:buffer)
+    let l:exec_args = l:executable =~? 'bundle$'
+    \   ? ' exec mdl'
+    \   : ''
+
+    let l:options = ale#Var(a:buffer, 'markdown_mdl_options')
+
+    return ale#Escape(l:executable) . l:exec_args
+    \   . ' -j' . (!empty(l:options) ? ' ' . l:options : '')
+endfunction
+
+function! ale_linters#markdown#mdl#Handle(buffer, lines) abort
+    let l:output = []
+
+    for l:error in ale#util#FuzzyJSONDecode(a:lines, [])
+        call add(l:output, {
+        \   'lnum': l:error['line'],
+        \   'code': l:error['rule']  . '/' . join(l:error['aliases'], '/'),
+        \   'text': l:error['description'],
+        \   'type': 'W',
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('markdown', {
+\   'name': 'mdl',
+\   'executable': function('ale_linters#markdown#mdl#GetExecutable'),
+\   'command': function('ale_linters#markdown#mdl#GetCommand'),
+\   'callback': 'ale_linters#markdown#mdl#Handle'
+\})

sources_non_forked/ale/ale_linters/markdown/proselint.vim

@@ -0,0 +1,9 @@
+" Author: poohzrn https://github.com/poohzrn
+" Description: proselint for Markdown files
+
+call ale#linter#Define('markdown', {
+\   'name': 'proselint',
+\   'executable': 'proselint',
+\   'command': 'proselint %t',
+\   'callback': 'ale#handlers#unix#HandleAsWarning',
+\})

sources_non_forked/ale/ale_linters/markdown/redpen.vim

@@ -0,0 +1,9 @@
+" Author: rhysd https://rhysd.github.io
+" Description: Redpen, a proofreading tool (http://redpen.cc)
+
+call ale#linter#Define('markdown', {
+\   'name': 'redpen',
+\   'executable': 'redpen',
+\   'command': 'redpen -f markdown -r json %t',
+\   'callback': 'ale#handlers#redpen#HandleRedpenOutput',
+\})

sources_non_forked/ale/ale_linters/markdown/remark_lint.vim

@@ -0,0 +1,48 @@
+scriptencoding utf-8
+" Author rhysd https://rhysd.github.io/, Dirk Roorda (dirkroorda), Adrián González Rus (@adrigzr)
+" Description: remark-lint for Markdown files
+call ale#Set('markdown_remark_lint_executable', 'remark')
+call ale#Set('markdown_remark_lint_use_global', get(g:, 'ale_use_global_executables', 0))
+call ale#Set('markdown_remark_lint_options', '')
+
+function! ale_linters#markdown#remark_lint#GetCommand(buffer) abort
+    let l:options = ale#Var(a:buffer, 'markdown_remark_lint_options')
+
+    return '%e' . ale#Pad(l:options) . ' --no-stdout --no-color'
+endfunction
+
+function! ale_linters#markdown#remark_lint#Handle(buffer, lines) abort
+    " matches: '  1:4  warning  Incorrect list-item indent: add 1 space  list-item-indent  remark-lint'
+    " matches: '  18:71-19:1  error  Missing new line after list item  list-item-spacing  remark-lint',
+    let l:pattern = '^ \+\(\d\+\):\(\d\+\)\(-\(\d\+\):\(\d\+\)\)\?  \(warning\|error\)  \(.\+\)$'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        let l:item = {
+        \   'lnum': l:match[1] + 0,
+        \   'col': l:match[2] + 0,
+        \   'type': l:match[6] is# 'error' ? 'E' : 'W',
+        \   'text': l:match[7],
+        \}
+
+        if l:match[3] isnot# ''
+            let l:item.end_lnum = l:match[4] + 0
+            let l:item.end_col = l:match[5] + 0
+        endif
+
+        call add(l:output, l:item)
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('markdown', {
+\   'name': 'remark_lint',
+\   'aliases': ['remark-lint'],
+\   'executable': {b -> ale#path#FindExecutable(b, 'markdown_remark_lint', [
+\       'node_modules/.bin/remark',
+\   ])},
+\   'command': function('ale_linters#markdown#remark_lint#GetCommand'),
+\   'callback': 'ale_linters#markdown#remark_lint#Handle',
+\   'output_stream': 'stderr',
+\})

sources_non_forked/ale/ale_linters/markdown/textlint.vim

@@ -0,0 +1,9 @@
+" Author: tokida https://rouger.info, Yasuhiro Kiyota <yasuhiroki.duck@gmail.com>
+" Description: textlint, a proofreading tool (https://textlint.github.io/)
+
+call ale#linter#Define('markdown', {
+\   'name': 'textlint',
+\   'executable': function('ale#handlers#textlint#GetExecutable'),
+\   'command': function('ale#handlers#textlint#GetCommand'),
+\   'callback': 'ale#handlers#textlint#HandleTextlintOutput',
+\})

sources_non_forked/ale/ale_linters/markdown/vale.vim

@@ -0,0 +1,24 @@
+" Author: chew-z https://github.com/chew-z
+" Description: vale for Markdown files
+
+call ale#Set('markdown_vale_executable', 'vale')
+call ale#Set('markdown_vale_input_file', '%t')
+call ale#Set('markdown_vale_options', '')
+
+function! ale_linters#markdown#vale#GetCommand(buffer) abort
+    let l:executable = ale#Var(a:buffer, 'markdown_vale_executable')
+    let l:input_file = ale#Var(a:buffer, 'markdown_vale_input_file')
+
+    " Defaults to `vale --output=JSON %t`
+    return ale#Escape(l:executable)
+    \   . ' --output=JSON '
+    \   . ale#Var(a:buffer, 'markdown_vale_options')
+    \   . ' ' . l:input_file
+endfunction
+
+call ale#linter#Define('markdown', {
+\   'name': 'vale',
+\   'executable': {b -> ale#Var(b, 'markdown_vale_executable')},
+\   'command': function('ale_linters#markdown#vale#GetCommand'),
+\   'callback': 'ale#handlers#vale#Handle',
+\})

sources_non_forked/ale/ale_linters/markdown/writegood.vim

@@ -0,0 +1,4 @@
+" Author: Sumner Evans <sumner.evans98@gmail.com>
+" Description: write-good for Markdown files
+
+call ale#handlers#writegood#DefineLinter('markdown')