gitignore sources_non_forked_cache

sources_non_forked/ale/ale_linters/puppet/languageserver.vim

@@ -0,0 +1,37 @@
+" Author: Alexander Olofsson <alexander.olofsson@liu.se>
+" Description: Puppet Language Server integration for ALE
+
+call ale#Set('puppet_languageserver_executable', 'puppet-languageserver')
+
+function! ale_linters#puppet#languageserver#GetProjectRoot(buffer) abort
+    " Note: The metadata.json file is recommended for Puppet 4+ modules, but
+    " there's no requirement to have it, so fall back to the other possible
+    " Puppet module directories
+    let l:root_path = ale#path#FindNearestFile(a:buffer, 'metadata.json')
+
+    if !empty(l:root_path)
+        return fnamemodify(l:root_path, ':h')
+    endif
+
+    for l:test_path in [
+    \   'manifests',
+    \   'templates',
+    \]
+        let l:root_path = ale#path#FindNearestDirectory(a:buffer, l:test_path)
+
+        if !empty(l:root_path)
+            return fnamemodify(l:root_path, ':h:h')
+        endif
+    endfor
+
+    return ''
+endfunction
+
+call ale#linter#Define('puppet', {
+\   'name': 'languageserver',
+\   'lsp': 'stdio',
+\   'executable': {b -> ale#Var(b, 'puppet_languageserver_executable')},
+\   'command': '%e --stdio',
+\   'language': 'puppet',
+\   'project_root': function('ale_linters#puppet#languageserver#GetProjectRoot'),
+\})

sources_non_forked/ale/ale_linters/puppet/puppet.vim

@@ -0,0 +1,39 @@
+" Author: Alexander Olofsson <alexander.olofsson@liu.se>
+
+call ale#Set('puppet_puppet_executable', 'puppet')
+call ale#Set('puppet_puppet_options', '')
+
+function! ale_linters#puppet#puppet#Handle(buffer, lines) abort
+    " Matches patterns like the following:
+    " Error: Could not parse for environment production: Syntax error at ':' at /root/puppetcode/modules/nginx/manifests/init.pp:43:12
+    " Error: Could not parse for environment production: Syntax error at '='; expected '}' at /root/puppetcode/modules/pancakes/manifests/init.pp:5"
+    " Error: Could not parse for environment production: Syntax error at 'parameter1' (file: /tmp/modules/mariadb/manifests/slave.pp, line: 4, column: 5)
+    " Error: Illegal attempt to assign to 'a Name'. Not an assignable reference (file: /tmp/modules/waffles/manifests/syrup.pp, line: 5, column: 11)
+    " Error: Could not parse for environment production: Syntax error at end of input (file: /tmp/modules/bob/manifests/init.pp)
+    let l:pattern = '^Error:\%(.*:\)\? \(.\+\) \((file:\|at\) .\+\.pp\(\(, line: \|:\)\(\d\+\)\(, column: \|:\)\=\(\d*\)\|)$\)'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        call add(l:output, {
+        \   'lnum': l:match[5] + 0,
+        \   'col': l:match[7] + 0,
+        \   'text': l:match[1],
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+function! ale_linters#puppet#puppet#GetCommand(buffer) abort
+    return '%e parser validate --color=false '
+    \    . ale#Pad(ale#Var(a:buffer, 'puppet_puppet_options'))
+    \    . ' %t'
+endfunction
+
+call ale#linter#Define('puppet', {
+\   'name': 'puppet',
+\   'executable': {b -> ale#Var(b, 'puppet_puppet_executable')},
+\   'output_stream': 'stderr',
+\   'command': function('ale_linters#puppet#puppet#GetCommand'),
+\   'callback': 'ale_linters#puppet#puppet#Handle',
+\})

sources_non_forked/ale/ale_linters/puppet/puppetlint.vim

@@ -0,0 +1,18 @@
+" Author: Alexander Olofsson <alexander.olofsson@liu.se>, Robert Flechtner <flechtner@chemmedia.de>
+" Description: puppet-lint for puppet files
+
+call ale#Set('puppet_puppetlint_executable', 'puppet-lint')
+call ale#Set('puppet_puppetlint_options', '--no-autoloader_layout-check')
+
+function! ale_linters#puppet#puppetlint#GetCommand(buffer) abort
+    return '%e' . ale#Pad(ale#Var(a:buffer, 'puppet_puppetlint_options'))
+    \   . ' --log-format "-:%{line}:%{column}: %{kind}: [%{check}] %{message}"'
+    \   . ' %t'
+endfunction
+
+call ale#linter#Define('puppet', {
+\   'name': 'puppetlint',
+\   'executable': {b -> ale#Var(b, 'puppet_puppetlint_executable')},
+\   'command': function('ale_linters#puppet#puppetlint#GetCommand'),
+\   'callback': 'ale#handlers#gcc#HandleGCCFormat',
+\})