gitignore sources_non_forked_cache

sources_non_forked/ale/ale_linters/ruby/brakeman.vim

@@ -0,0 +1,51 @@
+" Author: Eddie Lebow https://github.com/elebow
+" Description: Brakeman, a static analyzer for Rails security
+
+call ale#Set('ruby_brakeman_options', '')
+call ale#Set('ruby_brakeman_executable', 'brakeman')
+call ale#Set('ruby_brakeman_options', '')
+
+function! ale_linters#ruby#brakeman#Handle(buffer, lines) abort
+    let l:output = []
+    let l:json = ale#util#FuzzyJSONDecode(a:lines, {})
+    let l:sep = has('win32') ? '\' : '/'
+    " Brakeman always outputs paths relative to the Rails app root
+    let l:rails_root = ale#ruby#FindRailsRoot(a:buffer)
+
+    for l:warning in get(l:json, 'warnings', [])
+        let l:text = l:warning.warning_type . ' ' . l:warning.message . ' (' . l:warning.confidence . ')'
+        let l:line = l:warning.line != v:null ? l:warning.line : 1
+
+        call add(l:output, {
+        \   'filename': l:rails_root . l:sep .  l:warning.file,
+        \   'lnum': l:line,
+        \   'type': 'W',
+        \   'text': l:text,
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+function! ale_linters#ruby#brakeman#GetCommand(buffer) abort
+    let l:rails_root = ale#ruby#FindRailsRoot(a:buffer)
+
+    if l:rails_root is? ''
+        return ''
+    endif
+
+    let l:executable = ale#Var(a:buffer, 'ruby_brakeman_executable')
+
+    return ale#ruby#EscapeExecutable(l:executable, 'brakeman')
+    \    . ' -f json -q '
+    \    . ale#Var(a:buffer, 'ruby_brakeman_options')
+    \    . ' -p ' . ale#Escape(l:rails_root)
+endfunction
+
+call ale#linter#Define('ruby', {
+\    'name': 'brakeman',
+\    'executable': {b -> ale#Var(b, 'ruby_brakeman_executable')},
+\    'command': function('ale_linters#ruby#brakeman#GetCommand'),
+\    'callback': 'ale_linters#ruby#brakeman#Handle',
+\    'lint_file': 1,
+\})

sources_non_forked/ale/ale_linters/ruby/cspell.vim

@@ -0,0 +1,5 @@
+scriptencoding utf-8
+" Author: David Houston <houstdav000>
+" Description: cspell support for Ruby files.
+
+call ale#handlers#cspell#DefineLinter('ruby')

sources_non_forked/ale/ale_linters/ruby/debride.vim

@@ -0,0 +1,42 @@
+" Author: Eddie Lebow https://github.com/elebow
+" Description: debride, a dead method detector for Ruby files
+
+call ale#Set('ruby_debride_executable', 'debride')
+call ale#Set('ruby_debride_options', '')
+
+function! ale_linters#ruby#debride#GetCommand(buffer) abort
+    let l:executable = ale#Var(a:buffer, 'ruby_debride_executable')
+
+    return ale#ruby#EscapeExecutable(l:executable, 'debride')
+    \   . ale#Var(a:buffer, 'ruby_debride_options')
+    \   . ' %s'
+endfunction
+
+function! ale_linters#ruby#debride#HandleOutput(buffer, lines) abort
+    let l:output = []
+
+    for l:line in a:lines
+        if l:line !~# '^  '
+            continue
+        endif
+
+        let l:elements = split(l:line)
+        let l:method_name = l:elements[0]
+        let l:lnum = split(l:elements[1], ':')[1]
+
+        call add(l:output, {
+        \   'lnum': 0 + l:lnum,
+        \   'text': 'Possible unused method: ' . l:method_name,
+        \   'type': 'W',
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('ruby', {
+\   'name': 'debride',
+\   'executable': {b -> ale#Var(b, 'ruby_debride_executable')},
+\   'command': function('ale_linters#ruby#debride#GetCommand'),
+\   'callback': 'ale_linters#ruby#debride#HandleOutput',
+\})

sources_non_forked/ale/ale_linters/ruby/rails_best_practices.vim

@@ -0,0 +1,49 @@
+" Author: Eddie Lebow https://github.com/elebow
+" Description: rails_best_practices, a code metric tool for rails projects
+
+call ale#Set('ruby_rails_best_practices_options', '')
+call ale#Set('ruby_rails_best_practices_executable', 'rails_best_practices')
+
+function! ale_linters#ruby#rails_best_practices#Handle(buffer, lines) abort
+    let l:output = []
+
+    for l:warning in ale#util#FuzzyJSONDecode(a:lines, [])
+        if !ale#path#IsBufferPath(a:buffer, l:warning.filename)
+            continue
+        endif
+
+        call add(l:output, {
+        \    'lnum': l:warning.line_number + 0,
+        \    'type': 'W',
+        \    'text': l:warning.message,
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+function! ale_linters#ruby#rails_best_practices#GetCommand(buffer) abort
+    let l:rails_root = ale#ruby#FindRailsRoot(a:buffer)
+
+    if l:rails_root is? ''
+        return ''
+    endif
+
+    let l:executable = ale#Var(a:buffer, 'ruby_rails_best_practices_executable')
+    let l:output_file = has('win32') ? '%t ' : '/dev/stdout '
+    let l:cat_file = has('win32') ? '; type %t' : ''
+
+    return ale#ruby#EscapeExecutable(l:executable, 'rails_best_practices')
+    \    . ' --silent -f json --output-file ' . l:output_file
+    \    . ale#Var(a:buffer, 'ruby_rails_best_practices_options')
+    \    . ale#Escape(l:rails_root)
+    \    . l:cat_file
+endfunction
+
+call ale#linter#Define('ruby', {
+\    'name': 'rails_best_practices',
+\    'executable': {b -> ale#Var(b, 'ruby_rails_best_practices_executable')},
+\    'command': function('ale_linters#ruby#rails_best_practices#GetCommand'),
+\    'callback': 'ale_linters#ruby#rails_best_practices#Handle',
+\    'lint_file': 1,
+\})

sources_non_forked/ale/ale_linters/ruby/reek.vim

@@ -0,0 +1,69 @@
+" Author: Eddie Lebow https://github.com/elebow
+" Description: Reek, a code smell detector for Ruby files
+
+call ale#Set('ruby_reek_show_context', 0)
+call ale#Set('ruby_reek_show_wiki_link', 0)
+call ale#Set('ruby_reek_options', '')
+call ale#Set('ruby_reek_executable', 'reek')
+
+function! ale_linters#ruby#reek#GetCommand(buffer, version) abort
+    let l:executable = ale#Var(a:buffer, 'ruby_reek_executable')
+
+    " Tell reek what the filename is if the version of reek is new enough.
+    let l:display_name_args = ale#semver#GTE(a:version, [5, 0, 0])
+    \   ? ' --stdin-filename %s'
+    \   : ''
+
+    return ale#ruby#EscapeExecutable(l:executable, 'reek')
+    \   . ' -f json --no-progress --no-color --force-exclusion'
+    \   . l:display_name_args
+endfunction
+
+function! s:GetDocumentationLink(error) abort
+    return get(a:error, 'documentation_link', get(a:error, 'wiki_link', ''))
+endfunction
+
+function! s:BuildText(buffer, error) abort
+    let l:parts = []
+
+    if ale#Var(a:buffer, 'ruby_reek_show_context')
+        call add(l:parts, a:error.context)
+    endif
+
+    call add(l:parts, a:error.message)
+
+    if ale#Var(a:buffer, 'ruby_reek_show_wiki_link')
+        call add(l:parts, '[' . s:GetDocumentationLink(a:error) . ']')
+    endif
+
+    return join(l:parts, ' ')
+endfunction
+
+function! ale_linters#ruby#reek#Handle(buffer, lines) abort
+    let l:output = []
+
+    for l:error in ale#util#FuzzyJSONDecode(a:lines, [])
+        for l:location in l:error.lines
+            call add(l:output, {
+            \    'lnum': l:location,
+            \    'type': 'W',
+            \    'text': s:BuildText(a:buffer, l:error),
+            \    'code': l:error.smell_type,
+            \})
+        endfor
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('ruby', {
+\   'name': 'reek',
+\   'executable': {b -> ale#Var(b, 'ruby_reek_executable')},
+\   'command': {buffer -> ale#semver#RunWithVersionCheck(
+\       buffer,
+\       ale#Var(buffer, 'ruby_reek_executable'),
+\       '%e --version',
+\       function('ale_linters#ruby#reek#GetCommand'),
+\   )},
+\    'callback': 'ale_linters#ruby#reek#Handle',
+\})

sources_non_forked/ale/ale_linters/ruby/rubocop.vim

@@ -0,0 +1,31 @@
+" Author: ynonp - https://github.com/ynonp, Eddie Lebow https://github.com/elebow
+" Description: RuboCop, a code style analyzer for Ruby files
+
+call ale#Set('ruby_rubocop_executable', 'rubocop')
+call ale#Set('ruby_rubocop_options', '')
+
+function! ale_linters#ruby#rubocop#GetCommand(buffer) abort
+    let l:executable = ale#Var(a:buffer, 'ruby_rubocop_executable')
+
+    return ale#ruby#EscapeExecutable(l:executable, 'rubocop')
+    \   . ' --format json --force-exclusion '
+    \   . ale#Var(a:buffer, 'ruby_rubocop_options')
+    \   . ' --stdin %s'
+endfunction
+
+function! ale_linters#ruby#rubocop#GetType(severity) abort
+    if a:severity is? 'convention'
+    \|| a:severity is? 'warning'
+    \|| a:severity is? 'refactor'
+        return 'W'
+    endif
+
+    return 'E'
+endfunction
+
+call ale#linter#Define('ruby', {
+\   'name': 'rubocop',
+\   'executable': {b -> ale#Var(b, 'ruby_rubocop_executable')},
+\   'command': function('ale_linters#ruby#rubocop#GetCommand'),
+\   'callback': 'ale#ruby#HandleRubocopOutput',
+\})

sources_non_forked/ale/ale_linters/ruby/ruby.vim

@@ -0,0 +1,12 @@
+" Author: Brandon Roehl - https://github.com/BrandonRoehl
+" Description: Ruby MRI for Ruby files
+
+call ale#Set('ruby_ruby_executable', 'ruby')
+
+call ale#linter#Define('ruby', {
+\   'name': 'ruby',
+\   'executable': {b -> ale#Var(b, 'ruby_ruby_executable')},
+\   'command': '%e -w -c %t',
+\   'output_stream': 'stderr',
+\   'callback': 'ale#handlers#ruby#HandleSyntaxErrors',
+\})

sources_non_forked/ale/ale_linters/ruby/solargraph.vim

@@ -0,0 +1,22 @@
+" Author: Horacio Sanson - https://github.com/hsanson
+" Description: Solargraph Language Server https://solargraph.org/
+"
+" Author: Devon Meunier <devon.meunier@gmail.com>
+" Description: updated to use stdio
+
+call ale#Set('ruby_solargraph_executable', 'solargraph')
+call ale#Set('ruby_solargraph_options', {})
+
+function! ale_linters#ruby#solargraph#GetCommand(buffer) abort
+    return '%e' . ale#Pad('stdio')
+endfunction
+
+call ale#linter#Define('ruby', {
+\   'name': 'solargraph',
+\   'lsp': 'stdio',
+\   'language': 'ruby',
+\   'executable': {b -> ale#Var(b, 'ruby_solargraph_executable')},
+\   'command': function('ale_linters#ruby#solargraph#GetCommand'),
+\   'project_root': function('ale#ruby#FindProjectRoot'),
+\   'initialization_options': {b -> ale#Var(b, 'ruby_solargraph_options')},
+\})

sources_non_forked/ale/ale_linters/ruby/sorbet.vim

@@ -0,0 +1,26 @@
+call ale#Set('ruby_sorbet_executable', 'srb')
+call ale#Set('ruby_sorbet_options', '')
+call ale#Set('ruby_sorbet_enable_watchman', 0)
+
+function! ale_linters#ruby#sorbet#GetCommand(buffer) abort
+    let l:executable = ale#Var(a:buffer, 'ruby_sorbet_executable')
+    let l:options = ale#Var(a:buffer, 'ruby_sorbet_options')
+    let l:enable_watchman = ale#Var(a:buffer, 'ruby_sorbet_enable_watchman')
+
+    return ale#ruby#EscapeExecutable(l:executable, 'srb')
+    \   . ' tc'
+    \   . (!empty(l:options) ? ' ' . l:options : '')
+    \   . ' --lsp'
+    \   . (l:enable_watchman ? '' : ' --disable-watchman')
+endfunction
+
+call ale#linter#Define('ruby', {
+\   'name': 'sorbet',
+\   'aliases': ['srb'],
+\   'lsp': 'stdio',
+\   'language': 'ruby',
+\   'executable': {b -> ale#Var(b, 'ruby_sorbet_executable')},
+\   'command': function('ale_linters#ruby#sorbet#GetCommand'),
+\   'project_root': function('ale#ruby#FindProjectRoot')
+\})
+

sources_non_forked/ale/ale_linters/ruby/standardrb.vim

@@ -0,0 +1,23 @@
+" Author: Justin Searls https://github.com/searls, ynonp - https://github.com/ynonp, Eddie Lebow https://github.com/elebow
+" based on the ale rubocop linter
+" Description: StandardRB - Ruby Style Guide, with linter & automatic code fixer
+
+call ale#Set('ruby_standardrb_executable', 'standardrb')
+call ale#Set('ruby_standardrb_options', '')
+
+function! ale_linters#ruby#standardrb#GetCommand(buffer) abort
+    let l:executable = ale#Var(a:buffer, 'ruby_standardrb_executable')
+
+    return ale#ruby#EscapeExecutable(l:executable, 'standardrb')
+    \   . ' --format json --force-exclusion '
+    \   . ale#Var(a:buffer, 'ruby_standardrb_options')
+    \   . ' --stdin %s'
+endfunction
+
+" standardrb is based on RuboCop so the callback is the same
+call ale#linter#Define('ruby', {
+\   'name': 'standardrb',
+\   'executable': {b -> ale#Var(b, 'ruby_standardrb_executable')},
+\   'command': function('ale_linters#ruby#standardrb#GetCommand'),
+\   'callback': 'ale#ruby#HandleRubocopOutput',
+\})