gitignore sources_non_forked_cache

sources_non_forked/ale/ale_linters/rust/analyzer.vim

@@ -0,0 +1,36 @@
+" Author: Jon Gjengset <jon@thesquareplanet.com>
+" Description: The next generation language server for Rust
+
+call ale#Set('rust_analyzer_executable', 'rust-analyzer')
+call ale#Set('rust_analyzer_config', {})
+
+function! ale_linters#rust#analyzer#GetCommand(buffer) abort
+    return '%e'
+endfunction
+
+function! ale_linters#rust#analyzer#GetProjectRoot(buffer) abort
+    " Try to find nearest Cargo.toml for cargo projects
+    let l:cargo_file = ale#path#FindNearestFile(a:buffer, 'Cargo.toml')
+
+    if !empty(l:cargo_file)
+        return fnamemodify(l:cargo_file, ':h')
+    endif
+
+    " Try to find nearest rust-project.json for non-cargo projects
+    let l:rust_project = ale#path#FindNearestFile(a:buffer, 'rust-project.json')
+
+    if !empty(l:rust_project)
+        return fnamemodify(l:rust_project, ':h')
+    endif
+
+    return ''
+endfunction
+
+call ale#linter#Define('rust', {
+\   'name': 'analyzer',
+\   'lsp': 'stdio',
+\   'initialization_options': {b -> ale#Var(b, 'rust_analyzer_config')},
+\   'executable': {b -> ale#Var(b, 'rust_analyzer_executable')},
+\   'command': function('ale_linters#rust#analyzer#GetCommand'),
+\   'project_root': function('ale_linters#rust#analyzer#GetProjectRoot'),
+\})

sources_non_forked/ale/ale_linters/rust/cargo.vim

@@ -0,0 +1,110 @@
+" Author: Daniel Schemala <istjanichtzufassen@gmail.com>,
+" Ivan Petkov <ivanppetkov@gmail.com>
+" Description: rustc invoked by cargo for rust files
+
+call ale#Set('rust_cargo_use_check', 1)
+call ale#Set('rust_cargo_check_all_targets', 0)
+call ale#Set('rust_cargo_check_examples', 0)
+call ale#Set('rust_cargo_check_tests', 0)
+call ale#Set('rust_cargo_avoid_whole_workspace', 1)
+call ale#Set('rust_cargo_default_feature_behavior', 'default')
+call ale#Set('rust_cargo_include_features', '')
+call ale#Set('rust_cargo_use_clippy', 0)
+call ale#Set('rust_cargo_clippy_options', '')
+call ale#Set('rust_cargo_target_dir', '')
+
+function! ale_linters#rust#cargo#GetCargoExecutable(bufnr) abort
+    if ale#path#FindNearestFile(a:bufnr, 'Cargo.toml') isnot# ''
+        return 'cargo'
+    else
+        " if there is no Cargo.toml file, we don't use cargo even if it exists,
+        " so we return '', because executable('') apparently always fails
+        return ''
+    endif
+endfunction
+
+function! ale_linters#rust#cargo#GetCwd(buffer) abort
+    if ale#Var(a:buffer, 'rust_cargo_avoid_whole_workspace')
+        let l:nearest_cargo = ale#path#FindNearestFile(a:buffer, 'Cargo.toml')
+        let l:nearest_cargo_dir = fnamemodify(l:nearest_cargo, ':h')
+
+        if l:nearest_cargo_dir isnot# '.'
+            return l:nearest_cargo_dir
+        endif
+    endif
+
+    return ''
+endfunction
+
+function! ale_linters#rust#cargo#GetCommand(buffer, version) abort
+    let l:use_check = ale#Var(a:buffer, 'rust_cargo_use_check')
+    \   && ale#semver#GTE(a:version, [0, 17, 0])
+    let l:use_all_targets = ale#Var(a:buffer, 'rust_cargo_check_all_targets')
+    \   && ale#semver#GTE(a:version, [0, 22, 0])
+    let l:use_examples = ale#Var(a:buffer, 'rust_cargo_check_examples')
+    \   && ale#semver#GTE(a:version, [0, 22, 0])
+    let l:use_tests = ale#Var(a:buffer, 'rust_cargo_check_tests')
+    \   && ale#semver#GTE(a:version, [0, 22, 0])
+    let l:target_dir = ale#Var(a:buffer, 'rust_cargo_target_dir')
+    let l:use_target_dir = !empty(l:target_dir)
+    \   && ale#semver#GTE(a:version, [0, 17, 0])
+
+    let l:include_features = ale#Var(a:buffer, 'rust_cargo_include_features')
+
+    if !empty(l:include_features)
+        let l:include_features = ' --features ' . ale#Escape(l:include_features)
+    endif
+
+    let l:default_feature_behavior = ale#Var(a:buffer, 'rust_cargo_default_feature_behavior')
+
+    if l:default_feature_behavior is# 'all'
+        let l:include_features = ''
+        let l:default_feature = ' --all-features'
+    elseif l:default_feature_behavior is# 'none'
+        let l:default_feature = ' --no-default-features'
+    else
+        let l:default_feature = ''
+    endif
+
+    let l:subcommand = l:use_check ? 'check' : 'build'
+    let l:clippy_options = ''
+
+    if ale#Var(a:buffer, 'rust_cargo_use_clippy')
+        let l:subcommand = 'clippy'
+        let l:clippy_options = ale#Var(a:buffer, 'rust_cargo_clippy_options')
+
+        if l:clippy_options =~# '^-- '
+            let l:clippy_options = join(split(l:clippy_options, '-- '))
+        endif
+
+        if l:clippy_options isnot# ''
+            let l:clippy_options = ' -- ' . l:clippy_options
+        endif
+    endif
+
+    return 'cargo '
+    \   . l:subcommand
+    \   . (l:use_all_targets ? ' --all-targets' : '')
+    \   . (l:use_examples ? ' --examples' : '')
+    \   . (l:use_tests ? ' --tests' : '')
+    \   . (l:use_target_dir ? (' --target-dir ' . ale#Escape(l:target_dir)) : '')
+    \   . ' --frozen --message-format=json -q'
+    \   . l:default_feature
+    \   . l:include_features
+    \   . l:clippy_options
+endfunction
+
+call ale#linter#Define('rust', {
+\   'name': 'cargo',
+\   'executable': function('ale_linters#rust#cargo#GetCargoExecutable'),
+\   'cwd': function('ale_linters#rust#cargo#GetCwd'),
+\   'command': {buffer -> ale#semver#RunWithVersionCheck(
+\       buffer,
+\       ale_linters#rust#cargo#GetCargoExecutable(buffer),
+\       '%e --version',
+\       function('ale_linters#rust#cargo#GetCommand'),
+\   )},
+\   'callback': 'ale#handlers#rust#HandleRustErrors',
+\   'output_stream': 'both',
+\   'lint_file': 1,
+\})

sources_non_forked/ale/ale_linters/rust/cspell.vim

@@ -0,0 +1,5 @@
+scriptencoding utf-8
+" Author: David Houston <houstdav000>
+" Description: cspell support for Rust files.
+
+call ale#handlers#cspell#DefineLinter('rust')

sources_non_forked/ale/ale_linters/rust/rls.vim

@@ -0,0 +1,27 @@
+" Author: w0rp <devw0rp@gmail.com>
+" Description: A language server for Rust
+
+call ale#Set('rust_rls_executable', 'rls')
+call ale#Set('rust_rls_toolchain', '')
+call ale#Set('rust_rls_config', {})
+
+function! ale_linters#rust#rls#GetCommand(buffer) abort
+    let l:toolchain = ale#Var(a:buffer, 'rust_rls_toolchain')
+
+    return '%e' . (!empty(l:toolchain) ? ' +' . ale#Escape(l:toolchain) : '')
+endfunction
+
+function! ale_linters#rust#rls#GetProjectRoot(buffer) abort
+    let l:cargo_file = ale#path#FindNearestFile(a:buffer, 'Cargo.toml')
+
+    return !empty(l:cargo_file) ? fnamemodify(l:cargo_file, ':h') : ''
+endfunction
+
+call ale#linter#Define('rust', {
+\   'name': 'rls',
+\   'lsp': 'stdio',
+\   'lsp_config': {b -> ale#Var(b, 'rust_rls_config')},
+\   'executable': {b -> ale#Var(b, 'rust_rls_executable')},
+\   'command': function('ale_linters#rust#rls#GetCommand'),
+\   'project_root': function('ale_linters#rust#rls#GetProjectRoot'),
+\})

sources_non_forked/ale/ale_linters/rust/rustc.vim

@@ -0,0 +1,33 @@
+" Author: Daniel Schemala <istjanichtzufassen@gmail.com>
+" Description: rustc for rust files
+
+call ale#Set('rust_rustc_options', '--emit=mir -o /dev/null')
+
+function! ale_linters#rust#rustc#RustcCommand(buffer) abort
+    " Try to guess the library search path. If the project is managed by cargo,
+    " it's usually <project root>/target/debug/deps/ or
+    " <project root>/target/release/deps/
+    let l:cargo_file = ale#path#FindNearestFile(a:buffer, 'Cargo.toml')
+
+    if l:cargo_file isnot# ''
+        let l:root = fnamemodify(l:cargo_file, ':h')
+        let l:dependencies = ' -L ' . ale#Escape(ale#path#GetAbsPath(l:root, 'target/debug/deps'))
+        \   . ' -L ' . ale#Escape(ale#path#GetAbsPath(l:root, 'target/release/deps'))
+    else
+        let l:dependencies = ''
+    endif
+
+    let l:options = ale#Var(a:buffer, 'rust_rustc_options')
+
+    return 'rustc --error-format=json'
+    \   . (!empty(l:options) ? ' ' . l:options : '')
+    \   . l:dependencies . ' -'
+endfunction
+
+call ale#linter#Define('rust', {
+\   'name': 'rustc',
+\   'executable': 'rustc',
+\   'command': function('ale_linters#rust#rustc#RustcCommand'),
+\   'callback': 'ale#handlers#rust#HandleRustErrors',
+\   'output_stream': 'stderr',
+\})