gitignore sources_non_forked_cache

sources_non_forked/ale/ale_linters/scss/sasslint.vim

@@ -0,0 +1,28 @@
+" Author: sQVe - https://github.com/sQVe
+
+call ale#Set('scss_sasslint_executable', 'sass-lint')
+call ale#Set('scss_sasslint_options', '')
+call ale#Set('scss_sasslint_use_global', get(g:, 'ale_use_global_executables', 0))
+
+function! ale_linters#scss#sasslint#GetExecutable(buffer) abort
+    return ale#path#FindExecutable(a:buffer, 'scss_sasslint', [
+    \   'node_modules/sass-lint/bin/sass-lint.js',
+    \   'node_modules/.bin/sass-lint',
+    \])
+endfunction
+
+function! ale_linters#scss#sasslint#GetCommand(buffer) abort
+    let l:executable = ale_linters#scss#sasslint#GetExecutable(a:buffer)
+    let l:options = ale#Var(a:buffer, 'scss_sasslint_options')
+
+    return ale#node#Executable(a:buffer, l:executable)
+    \   . (!empty(l:options) ? ' ' . l:options : '')
+    \   . ' -v -q -f compact %t'
+endfunction
+
+call ale#linter#Define('scss', {
+\   'name': 'sasslint',
+\   'executable': function('ale_linters#scss#sasslint#GetExecutable'),
+\   'command': function('ale_linters#scss#sasslint#GetCommand'),
+\   'callback': 'ale#handlers#css#HandleCSSLintFormat',
+\})

sources_non_forked/ale/ale_linters/scss/scsslint.vim

@@ -0,0 +1,34 @@
+" Author: w0rp <devw0rp@gmail.com>
+" Description: This file add scsslint support for SCSS support
+
+function! ale_linters#scss#scsslint#Handle(buffer, lines) abort
+    " Matches patterns like the following:
+    "
+    " test.scss:2:1 [W] Indentation: Line should be indented 2 spaces, but was indented 4 spaces
+    let l:pattern = '^.*:\(\d\+\):\(\d*\) \[\([^\]]\+\)\] \(.\+\)$'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        if !ale#Var(a:buffer, 'warn_about_trailing_whitespace')
+        \&& l:match[4] =~# '^TrailingWhitespace'
+            " Skip trailing whitespace warnings if that option is off.
+            continue
+        endif
+
+        call add(l:output, {
+        \   'lnum': l:match[1] + 0,
+        \   'col': l:match[2] + 0,
+        \   'text': l:match[4],
+        \   'type': l:match[3] is# 'E' ? 'E' : 'W',
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('scss', {
+\   'name': 'scsslint',
+\   'executable': 'scss-lint',
+\   'command': 'scss-lint --stdin-file-path=%s',
+\   'callback': 'ale_linters#scss#scsslint#Handle',
+\})

sources_non_forked/ale/ale_linters/scss/stylelint.vim

@@ -0,0 +1,19 @@
+" Author: diartyz <diartyz@gmail.com>
+
+call ale#Set('scss_stylelint_executable', 'stylelint')
+call ale#Set('scss_stylelint_options', '')
+call ale#Set('scss_stylelint_use_global', get(g:, 'ale_use_global_executables', 0))
+
+function! ale_linters#scss#stylelint#GetCommand(buffer) abort
+    return '%e ' . ale#Pad(ale#Var(a:buffer, 'scss_stylelint_options'))
+    \   . ' --stdin-filename %s'
+endfunction
+
+call ale#linter#Define('scss', {
+\   'name': 'stylelint',
+\   'executable': {b -> ale#path#FindExecutable(b, 'scss_stylelint', [
+\       'node_modules/.bin/stylelint',
+\   ])},
+\   'command': function('ale_linters#scss#stylelint#GetCommand'),
+\   'callback': 'ale#handlers#css#HandleStyleLintFormat',
+\})