gitignore sources_non_forked_cache

sources_non_forked/ale/ale_linters/swift/appleswiftformat.vim

@@ -0,0 +1,43 @@
+" Authors: Klaas Pieter Annema <https://github.com/klaaspieter>, bosr <bosr@bosr.cc>
+" Description: Support for swift-format https://github.com/apple/swift-format
+
+function! ale_linters#swift#appleswiftformat#GetLinterCommand(buffer) abort
+    let l:command_args = ale#swift#GetAppleSwiftFormatCommand(a:buffer) . ' lint %t'
+    let l:config_args = ale#swift#GetAppleSwiftFormatConfigArgs(a:buffer)
+
+    if l:config_args isnot# ''
+        let l:command_args = l:command_args . ' ' . l:config_args
+    endif
+
+    return l:command_args
+endfunction
+
+function! ale_linters#swift#appleswiftformat#Handle(buffer, lines) abort
+    " Matches the typical output of swift-format, that is lines of the following pattern:
+    "
+    " Sources/main.swift:4:21: warning: [DoNotUseSemicolons] remove ';' and move the next statement to the new line
+    " Sources/main.swift:3:12: warning: [Spacing] remove 1 space
+    let l:pattern = '\v^.*:(\d+):(\d+): (\S+): \[(\S+)\] (.*)$'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        call add(l:output, {
+        \   'lnum': l:match[1] + 0,
+        \   'col': l:match[2] + 0,
+        \   'type': l:match[3] is# 'error' ? 'E' : 'W',
+        \   'code': l:match[4],
+        \   'text': l:match[5],
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('swift', {
+\   'name': 'apple-swift-format',
+\   'executable': function('ale#swift#GetAppleSwiftFormatExecutable'),
+\   'command': function('ale_linters#swift#appleswiftformat#GetLinterCommand'),
+\   'output_stream': 'stderr',
+\   'language': 'swift',
+\   'callback': 'ale_linters#swift#appleswiftformat#Handle'
+\})

sources_non_forked/ale/ale_linters/swift/cspell.vim

@@ -0,0 +1,5 @@
+scriptencoding utf-8
+" Author: David Houston <houstdav000>
+" Description: cspell support for Swift files.
+
+call ale#handlers#cspell#DefineLinter('swift')

sources_non_forked/ale/ale_linters/swift/sourcekitlsp.vim

@@ -0,0 +1,13 @@
+" Author: Dan Loman <https://github.com/namolnad>
+" Description: Support for sourcekit-lsp https://github.com/apple/sourcekit-lsp
+
+call ale#Set('sourcekit_lsp_executable', 'sourcekit-lsp')
+
+call ale#linter#Define('swift', {
+\   'name': 'sourcekitlsp',
+\   'lsp': 'stdio',
+\   'executable': {b -> ale#Var(b, 'sourcekit_lsp_executable')},
+\   'command': '%e',
+\   'project_root': function('ale#swift#FindProjectRoot'),
+\   'language': 'swift',
+\})

sources_non_forked/ale/ale_linters/swift/swiftlint.vim

@@ -0,0 +1,69 @@
+" Author: David Mohundro <david@mohundro.com>, Gordon Fontenot <gordon@fonten.io>
+" Description: swiftlint for swift files
+
+call ale#Set('swift_swiftlint_executable', 'swiftlint')
+call ale#Set('swift_swiftlint_use_global', get(g:, 'ale_use_global_executables', 0))
+
+function! ale_linters#swift#swiftlint#GetExecutable(buffer) abort
+    return ale#path#FindExecutable(a:buffer, 'swift_swiftlint', [
+    \ 'Pods/SwiftLint/swiftlint',
+    \ 'ios/Pods/SwiftLint/swiftlint',
+    \ 'swiftlint',
+    \])
+endfunction
+
+function! ale_linters#swift#swiftlint#GetCommand(buffer) abort
+    let l:executable = ale_linters#swift#swiftlint#GetExecutable(a:buffer)
+    let l:args = 'lint --use-stdin'
+
+    return ale#Escape(l:executable)
+    \ . ' ' .l:args
+endfunction
+
+function! ale_linters#swift#swiftlint#Handle(buffer, lines) abort
+    let l:pattern = '\v^([a-zA-Z]?:?[^:]+):(\d+):(\d+)?:? ([^:]+): (.+)$'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        let l:item = {
+        \   'lnum': str2nr(l:match[2]),
+        \   'type': l:match[4] is# 'error' ? 'E' : 'W',
+        \   'text': l:match[5],
+        \}
+
+        if l:match[4] is# 'error'
+            let l:item.type = 'E'
+        elseif l:match[4] is# 'note'
+            let l:item.type = 'I'
+        endif
+
+        if !empty(l:match[3])
+            let l:item.col = str2nr(l:match[3])
+        endif
+
+        " If the filename is something like <stdin>, <nofile> or -, then
+        " this is an error for the file we checked.
+        if l:match[1] isnot# '-' && l:match[1][0] isnot# '<'
+            let l:item['filename'] = l:match[1]
+        endif
+
+        " Parse the code if it's there.
+        let l:code_match = matchlist(l:item.text, '\v^(.+) \(([^ (]+)\)$')
+
+        if !empty(l:code_match)
+            let l:item.text = l:code_match[1]
+            let l:item.code = l:code_match[2]
+        endif
+
+        call add(l:output, l:item)
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('swift', {
+\   'name': 'swiftlint',
+\   'executable': function('ale_linters#swift#swiftlint#GetExecutable'),
+\   'command': function('ale_linters#swift#swiftlint#GetCommand'),
+\   'callback': 'ale_linters#swift#swiftlint#Handle',
+\})