gitignore sources_non_forked_cache

sources_non_forked/ale/ale_linters/yaml/actionlint.vim

@@ -0,0 +1,11 @@
+" Author: bretello <bretello@distruzione.org>
+
+call ale#Set('yaml_actionlint_executable', 'actionlint')
+call ale#Set('yaml_actionlint_options', '')
+
+call ale#linter#Define('yaml', {
+\   'name': 'actionlint',
+\   'executable': {b -> ale#Var(b, 'yaml_actionlint_executable')},
+\   'command': function('ale#handlers#actionlint#GetCommand'),
+\   'callback': 'ale#handlers#actionlint#Handle',
+\})

sources_non_forked/ale/ale_linters/yaml/circleci.vim

@@ -0,0 +1,35 @@
+function! ale_linters#yaml#circleci#Handle(buffer, lines) abort
+    let l:match_index = -1
+    let l:output = []
+
+    for l:index in range(len(a:lines))
+        let l:line = a:lines[l:index]
+
+        if l:line =~? 'Error: ERROR IN CONFIG FILE:'
+            let l:match_index = l:index + 1
+            break
+        endif
+    endfor
+
+    if l:match_index > 0
+        return [{
+        \   'type': 'E',
+        \   'lnum': 1,
+        \   'text': a:lines[l:match_index],
+        \   'detail': join(a:lines[l:match_index :], "\n"),
+        \}]
+    endif
+
+    return []
+endfunction
+
+" The circleci validate requires network requests, so we'll only run it when
+" files are saved to prevent the server from being hammered.
+call ale#linter#Define('yaml', {
+\   'name': 'circleci',
+\   'executable': {b -> expand('#' . b . ':p') =~? '\.circleci' ? 'circleci' : ''},
+\   'command': 'circleci --skip-update-check config validate - < %s',
+\   'callback': 'ale_linters#yaml#circleci#Handle',
+\   'output_stream': 'stderr',
+\   'lint_file': 1,
+\})

sources_non_forked/ale/ale_linters/yaml/gitlablint.vim

@@ -0,0 +1,49 @@
+call ale#Set('yaml_gitlablint_executable', 'gll')
+call ale#Set('yaml_gitlablint_options', '')
+
+function! ale_linters#yaml#gitlablint#GetCommand(buffer) abort
+    return '%e' . ale#Pad(ale#Var(a:buffer, 'yaml_gitlablint_options'))
+    \   . ' -p %t'
+endfunction
+
+function! ale_linters#yaml#gitlablint#Handle(buffer, lines) abort
+    " Matches patterns line the following:
+    " (<unknown>): mapping values are not allowed in this context at line 68 column 8
+    " jobs:build:dev config contains unknown keys: ony
+    let l:pattern = '^\(.*\) at line \(\d\+\) column \(\d\+\)$'
+    let l:output = []
+
+    for l:line in a:lines
+        let l:match = matchlist(l:line, l:pattern)
+
+        if !empty(l:match)
+            let l:item = {
+            \   'lnum': l:match[2] + 0,
+            \   'col': l:match[3] + 0,
+            \   'text': l:match[1],
+            \   'type': 'E',
+            \}
+            call add(l:output, l:item)
+        else
+            if l:line isnot# 'GitLab CI configuration is invalid'
+                let l:item = {
+                \   'lnum': 0,
+                \   'col': 0,
+                \   'text': l:line,
+                \   'type': 'E',
+                \}
+                call add(l:output, l:item)
+            endif
+        endif
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('yaml', {
+\   'name': 'gitlablint',
+\   'executable': {b -> ale#Var(b, 'yaml_gitlablint_executable')},
+\   'command': function('ale_linters#yaml#gitlablint#GetCommand'),
+\   'callback': 'ale_linters#yaml#gitlablint#Handle',
+\   'output_stream': 'stderr',
+\})

sources_non_forked/ale/ale_linters/yaml/ls.vim

@@ -0,0 +1,34 @@
+" Author: Jeffrey Lau - https://github.com/zoonfafer
+" Description: YAML Language Server https://github.com/redhat-developer/yaml-language-server
+
+call ale#Set('yaml_ls_executable', 'yaml-language-server')
+call ale#Set('yaml_ls_use_global', get(g:, 'ale_use_global_executables', 0))
+call ale#Set('yaml_ls_config', {})
+
+function! ale_linters#yaml#ls#GetExecutable(buffer) abort
+    return ale#path#FindExecutable(a:buffer, 'yaml_ls', [
+    \   'node_modules/.bin/yaml-language-server',
+    \])
+endfunction
+
+function! ale_linters#yaml#ls#GetCommand(buffer) abort
+    let l:executable = ale_linters#yaml#ls#GetExecutable(a:buffer)
+
+    return ale#Escape(l:executable) . ' --stdio'
+endfunction
+
+" Just use the current file
+function! ale_linters#yaml#ls#FindProjectRoot(buffer) abort
+    let l:project_file = expand('#' . a:buffer . ':p')
+
+    return fnamemodify(l:project_file, ':h')
+endfunction
+
+call ale#linter#Define('yaml', {
+\   'name': 'yaml-language-server',
+\   'lsp': 'stdio',
+\   'executable': function('ale_linters#yaml#ls#GetExecutable'),
+\   'command': function('ale_linters#yaml#ls#GetCommand'),
+\   'project_root': function('ale_linters#yaml#ls#FindProjectRoot'),
+\   'lsp_config': {b -> ale#Var(b, 'yaml_ls_config')},
+\})

sources_non_forked/ale/ale_linters/yaml/spectral.vim

@@ -0,0 +1,14 @@
+" Author: t2h5 <https://github.com/t2h5>
+" Description: Integration of Stoplight Spectral CLI with ALE.
+
+call ale#Set('yaml_spectral_executable', 'spectral')
+call ale#Set('yaml_spectral_use_global', get(g:, 'ale_use_global_executables', 0))
+
+call ale#linter#Define('yaml', {
+\   'name': 'spectral',
+\   'executable': {b -> ale#path#FindExecutable(b, 'yaml_spectral', [
+\       'node_modules/.bin/spectral',
+\   ])},
+\   'command': '%e lint --ignore-unknown-format -q -f text %t',
+\   'callback': 'ale#handlers#spectral#HandleSpectralOutput'
+\})

sources_non_forked/ale/ale_linters/yaml/swaglint.vim

@@ -0,0 +1,40 @@
+" Author: Matthew Turland <https://github.com/elazar>
+" Description: This file adds support for linting Swagger / OpenAPI documents using swaglint
+
+call ale#Set('yaml_swaglint_executable', 'swaglint')
+call ale#Set('yaml_swaglint_use_global', get(g:, 'ale_use_global_executables', 0))
+
+function! ale_linters#yaml#swaglint#Handle(buffer, lines) abort
+    let l:pattern = ': \([^\s]\+\) @ \(\d\+\):\(\d\+\) - \(.\+\)$'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        let l:obj = {
+        \   'type': l:match[1] is# 'error' ? 'E' : 'W',
+        \   'lnum': l:match[2] + 0,
+        \   'col': l:match[3] + 0,
+        \   'text': l:match[4],
+        \}
+
+        " Parse the code if it's there.
+        let l:code_match = matchlist(l:obj.text, '\v^(.+) \(([^ (]+)\)$')
+
+        if !empty(l:code_match)
+            let l:obj.text = l:code_match[1]
+            let l:obj.code = l:code_match[2]
+        endif
+
+        call add(l:output, l:obj)
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('yaml', {
+\   'name': 'swaglint',
+\   'executable': {b -> ale#path#FindExecutable(b, 'yaml_swaglint', [
+\       'node_modules/.bin/swaglint',
+\   ])},
+\   'command': '%e -r compact --stdin',
+\   'callback': 'ale_linters#yaml#swaglint#Handle',
+\})

sources_non_forked/ale/ale_linters/yaml/yamllint.vim

@@ -0,0 +1,11 @@
+" Author: KabbAmine <amine.kabb@gmail.com>
+
+call ale#Set('yaml_yamllint_executable', 'yamllint')
+call ale#Set('yaml_yamllint_options', '')
+
+call ale#linter#Define('yaml', {
+\   'name': 'yamllint',
+\   'executable': {b -> ale#Var(b, 'yaml_yamllint_executable')},
+\   'command': function('ale#handlers#yamllint#GetCommand'),
+\   'callback': 'ale#handlers#yamllint#Handle',
+\})