gitignore sources_non_forked_cache

sources_non_forked/vim-coffee-script/after/indent/html.vim

@@ -0,0 +1,33 @@
+" Language:    CoffeeScript
+" Maintainer:  Mick Koch <mick@kochm.co>
+" URL:         http://github.com/kchmck/vim-coffee-script
+" License:     WTFPL
+
+" Load the coffee and html indent functions.
+silent! unlet b:did_indent
+runtime indent/coffee.vim
+let s:coffeeIndentExpr = &l:indentexpr
+
+" Load html last so it can overwrite coffee settings.
+silent! unlet b:did_indent
+runtime indent/html.vim
+let s:htmlIndentExpr = &l:indentexpr
+
+" Inject our wrapper indent function.
+setlocal indentexpr=GetCoffeeHtmlIndent(v:lnum)
+
+function! GetCoffeeHtmlIndent(curlinenum)
+  " See if we're inside a coffeescript block.
+  let scriptlnum = searchpair('<script [^>]*type=[''"]\?text/coffeescript[''"]\?[^>]*>', '',
+  \                           '</script>', 'bWn')
+  let prevlnum = prevnonblank(a:curlinenum)
+
+  " If we're in the script block and the previous line isn't the script tag
+  " itself, use coffee indenting.
+  if scriptlnum && scriptlnum != prevlnum
+    exec 'return ' s:coffeeIndentExpr
+  endif
+
+  " Otherwise use html indenting.
+  exec 'return ' s:htmlIndentExpr
+endfunction

sources_non_forked/vim-coffee-script/after/syntax/haml.vim

@@ -0,0 +1,23 @@
+" Language:    CoffeeScript
+" Maintainer:  Sven Felix Oberquelle <Svelix.Github@gmail.com>
+" URL:         http://github.com/kchmck/vim-coffee-script
+" License:     WTFPL
+
+
+if exists('b:current_syntax')
+  let s:current_syntax_save = b:current_syntax
+endif
+
+" Inherit coffee from html so coffeeComment isn't redefined and given higher
+" priority than hamlInterpolation.
+syn cluster hamlCoffeescript contains=@htmlCoffeeScript
+syn region  hamlCoffeescriptFilter matchgroup=hamlFilter
+\                                  start="^\z(\s*\):coffee\z(script\)\?\s*$"
+\                                  end="^\%(\z1 \| *$\)\@!"
+\                                  contains=@hamlCoffeeScript,hamlInterpolation
+\                                  keepend
+
+if exists('s:current_syntax_save')
+  let b:current_syntax = s:current_syntax_save
+  unlet s:current_syntax_save
+endif

sources_non_forked/vim-coffee-script/after/syntax/html.vim

@@ -0,0 +1,20 @@
+" Language:    CoffeeScript
+" Maintainer:  Mick Koch <mick@kochm.co>
+" URL:         http://github.com/kchmck/vim-coffee-script
+" License:     WTFPL
+
+if exists('b:current_syntax')
+  let s:current_syntax_save = b:current_syntax
+endif
+
+" Syntax highlighting for text/coffeescript script tags
+syn include @htmlCoffeeScript syntax/coffee.vim
+syn region coffeeScript start=#<script [^>]*type=['"]\?text/coffeescript['"]\?[^>]*>#
+\                       end=#</script>#me=s-1 keepend
+\                       contains=@htmlCoffeeScript,htmlScriptTag,@htmlPreproc
+\                       containedin=htmlHead
+
+if exists('s:current_syntax_save')
+  let b:current_syntax = s:current_syntax_save
+  unlet s:current_syntax_save
+endif