Use syntastic instead of pyflakes (supports a ton of more languages)

sources_non_forked/syntastic/syntax_checkers/puppet/puppet.vim

@@ -0,0 +1,50 @@
+"============================================================================
+"File:        puppet.vim
+"Description: Syntax checking plugin for syntastic.vim
+"Maintainer:  Eivind Uggedal <eivind at uggedal dot com>
+"License:     This program is free software. It comes without any warranty,
+"             to the extent permitted by applicable law. You can redistribute
+"             it and/or modify it under the terms of the Do What The Fuck You
+"             Want To Public License, Version 2, as published by Sam Hocevar.
+"             See http://sam.zoy.org/wtfpl/COPYING for more details.
+"
+"============================================================================
+
+if exists("g:loaded_syntastic_puppet_puppet_checker")
+    finish
+endif
+let g:loaded_syntastic_puppet_puppet_checker = 1
+
+let s:save_cpo = &cpo
+set cpo&vim
+
+function! SyntaxCheckers_puppet_puppet_GetLocList() dict
+    let ver = syntastic#util#getVersion(self.getExecEscaped() . ' --version 2>' . syntastic#util#DevNull())
+
+    if syntastic#util#versionIsAtLeast(ver, [2,7,0])
+        let args = 'parser validate --color=false'
+    else
+        let args = '--color=false --parseonly'
+    endif
+
+    let makeprg = self.makeprgBuild({ 'args_before': args })
+
+    let errorformat =
+        \ '%-Gerr: Try ''puppet help parser validate'' for usage,' .
+        \ '%-GError: Try ''puppet help parser validate'' for usage,' .
+        \ '%Eerr: Could not parse for environment %*[a-z]: %m at %f:%l,' .
+        \ '%EError: Could not parse for environment %*[a-z]: %m at %f:%l'
+
+    return SyntasticMake({
+        \ 'makeprg': makeprg,
+        \ 'errorformat': errorformat })
+endfunction
+
+call g:SyntasticRegistry.CreateAndRegisterChecker({
+    \ 'filetype': 'puppet',
+    \ 'name': 'puppet'})
+
+let &cpo = s:save_cpo
+unlet s:save_cpo
+
+" vim: set et sts=4 sw=4:

sources_non_forked/syntastic/syntax_checkers/puppet/puppetlint.vim

@@ -0,0 +1,53 @@
+"============================================================================
+"File:        puppetlint.vim
+"Description: Syntax checking plugin for syntastic.vim
+"Maintainer:  Eivind Uggedal <eivind at uggedal dot com>
+"License:     This program is free software. It comes without any warranty,
+"             to the extent permitted by applicable law. You can redistribute
+"             it and/or modify it under the terms of the Do What The Fuck You
+"             Want To Public License, Version 2, as published by Sam Hocevar.
+"             See http://sam.zoy.org/wtfpl/COPYING for more details.
+"
+"============================================================================
+
+if exists("g:loaded_syntastic_puppet_puppetlint_checker")
+    finish
+endif
+let g:loaded_syntastic_puppet_puppetlint_checker = 1
+
+let s:save_cpo = &cpo
+set cpo&vim
+
+if exists("g:syntastic_puppet_lint_arguments")
+    let g:syntastic_puppet_puppetlint_args = g:syntastic_puppet_lint_arguments
+    call syntastic#log#deprecationWarn("variable g:syntastic_puppet_lint_arguments is deprecated, please use g:syntastic_puppet_puppetlint_args instead")
+endif
+
+function! SyntaxCheckers_puppet_puppetlint_IsAvailable() dict
+    return
+        \ executable("puppet") &&
+        \ executable("puppet-lint") &&
+        \ syntastic#util#versionIsAtLeast(syntastic#util#getVersion('puppet-lint --version 2>' .
+        \     syntastic#util#DevNull()), [0,1,10])
+endfunction
+
+function! SyntaxCheckers_puppet_puppetlint_GetLocList() dict
+    let makeprg = self.makeprgBuild({
+        \ 'args_after': '--log-format "%{KIND} [%{check}] %{message} at %{fullpath}:%{linenumber}"' })
+
+    let errorformat = '%t%*[a-zA-Z] %m at %f:%l'
+
+    return SyntasticMake({
+        \ 'makeprg': makeprg,
+        \ 'errorformat': errorformat })
+endfunction
+
+call g:SyntasticRegistry.CreateAndRegisterChecker({
+    \ 'filetype': 'puppet',
+    \ 'name': 'puppetlint',
+    \ 'exec': 'puppet-lint'})
+
+let &cpo = s:save_cpo
+unlet s:save_cpo
+
+" vim: set et sts=4 sw=4: