Use syntastic instead of pyflakes (supports a ton of more languages)

sources_non_forked/syntastic/syntax_checkers/sh/checkbashisms.vim

@@ -0,0 +1,42 @@
+"============================================================================
+"File:        checkbashisms.vim
+"Description: Shell script syntax/style checking plugin for syntastic.vim
+"Notes:       checkbashisms.pl can be downloaded from
+"             http://debian.inode.at/debian/pool/main/d/devscripts/
+"             as part of the devscripts package.
+"============================================================================
+
+if exists("g:loaded_syntastic_sh_checkbashisms_checker")
+    finish
+endif
+let g:loaded_syntastic_sh_checkbashisms_checker = 1
+
+let s:save_cpo = &cpo
+set cpo&vim
+
+function! SyntaxCheckers_sh_checkbashisms_GetLocList() dict
+    let makeprg = self.makeprgBuild({ 'args': '-fx' })
+
+    let errorformat =
+        \ '%-Gscript %f is already a bash script; skipping,' .
+        \ '%Eerror: %f: %m\, opened in line %l,' .
+        \ '%Eerror: %f: %m,' .
+        \ '%Ecannot open script %f for reading: %m,' .
+        \ '%Wscript %f %m,%C%.# lines,' .
+        \ '%Wpossible bashism in %f line %l (%m):,%C%.%#,%Z.%#,' .
+        \ '%-G%.%#'
+
+    return SyntasticMake({
+        \ 'makeprg': makeprg,
+        \ 'errorformat': errorformat,
+        \ 'subtype': 'Style' })
+endfunction
+
+call g:SyntasticRegistry.CreateAndRegisterChecker({
+    \ 'filetype': 'sh',
+    \ 'name': 'checkbashisms' })
+
+let &cpo = s:save_cpo
+unlet s:save_cpo
+
+" vim: set et sts=4 sw=4:

sources_non_forked/syntastic/syntax_checkers/sh/sh.vim

@@ -0,0 +1,88 @@
+"============================================================================
+"File:        sh.vim
+"Description: Syntax checking plugin for syntastic.vim
+"Maintainer:  Gregor Uhlenheuer <kongo2002 at gmail dot com>
+"License:     This program is free software. It comes without any warranty,
+"             to the extent permitted by applicable law. You can redistribute
+"             it and/or modify it under the terms of the Do What The Fuck You
+"             Want To Public License, Version 2, as published by Sam Hocevar.
+"             See http://sam.zoy.org/wtfpl/COPYING for more details.
+"
+"============================================================================
+
+if exists("g:loaded_syntastic_sh_sh_checker")
+    finish
+endif
+let g:loaded_syntastic_sh_sh_checker = 1
+
+let s:save_cpo = &cpo
+set cpo&vim
+
+function! s:GetShell()
+    if !exists('b:shell') || b:shell == ''
+        let b:shell = ''
+        let shebang = getbufline(bufnr('%'), 1)[0]
+        if shebang != ''
+            if stridx(shebang, 'bash') >= 0
+                let b:shell = 'bash'
+            elseif stridx(shebang, 'zsh') >= 0
+                let b:shell = 'zsh'
+            elseif stridx(shebang, 'sh') >= 0
+                let b:shell = 'sh'
+            endif
+        endif
+        " try to use env variable in case no shebang could be found
+        if b:shell == ''
+            let b:shell = fnamemodify(expand('$SHELL'), ':t')
+        endif
+    endif
+    return b:shell
+endfunction
+
+function! s:ForwardToZshChecker()
+    let registry = g:SyntasticRegistry.Instance()
+    if registry.checkable('zsh')
+        return registry.getCheckers('zsh', ['zsh'])[0].getLocListRaw()
+    else
+        return []
+    endif
+
+endfunction
+
+function! s:IsShellValid()
+    return len(s:GetShell()) > 0 && executable(s:GetShell())
+endfunction
+
+
+function! SyntaxCheckers_sh_sh_IsAvailable() dict
+    return s:IsShellValid()
+endfunction
+
+function! SyntaxCheckers_sh_sh_GetLocList() dict
+    if s:GetShell() ==# 'zsh'
+        return s:ForwardToZshChecker()
+    endif
+
+    if !s:IsShellValid()
+        return []
+    endif
+
+    let makeprg = self.makeprgBuild({
+        \ 'exe': s:GetShell(),
+        \ 'args_after': '-n' })
+
+    let errorformat = '%f: line %l: %m'
+
+    return SyntasticMake({
+        \ 'makeprg': makeprg,
+        \ 'errorformat': errorformat })
+endfunction
+
+call g:SyntasticRegistry.CreateAndRegisterChecker({
+    \ 'filetype': 'sh',
+    \ 'name': 'sh' })
+
+let &cpo = s:save_cpo
+unlet s:save_cpo
+
+" vim: set et sts=4 sw=4:

sources_non_forked/syntastic/syntax_checkers/sh/shellcheck.vim

@@ -0,0 +1,44 @@
+"============================================================================
+"File:        shellcheck.vim
+"Description: Shell script syntax/style checking plugin for syntastic.vim
+"============================================================================
+
+if exists("g:loaded_syntastic_sh_shellcheck_checker")
+    finish
+endif
+let g:loaded_syntastic_sh_shellcheck_checker = 1
+
+let s:save_cpo = &cpo
+set cpo&vim
+
+function! SyntaxCheckers_sh_shellcheck_GetLocList() dict
+    let makeprg = self.makeprgBuild({ 'args_after': '-f gcc' })
+
+    let errorformat =
+        \ '%f:%l:%c: %trror: %m,' .
+        \ '%f:%l:%c: %tarning: %m,' .
+        \ '%f:%l:%c: %tote: %m'
+
+    let loclist = SyntasticMake({
+        \ 'makeprg': makeprg,
+        \ 'errorformat': errorformat,
+        \ 'returns': [0, 1] })
+
+    for e in loclist
+        if e['type'] ==? 'n'
+            let e['type'] = 'w'
+            let e['subtype'] = 'Style'
+        endif
+    endfor
+
+    return loclist
+endfunction
+
+call g:SyntasticRegistry.CreateAndRegisterChecker({
+    \ 'filetype': 'sh',
+    \ 'name': 'shellcheck' })
+
+let &cpo = s:save_cpo
+unlet s:save_cpo
+
+" vim: set et sts=4 sw=4: