Removed syntastic and replaced it with ale

Read more here:
https://github.com/w0rp/ale

sources_non_forked/ale/ale_linters/go/gobuild.vim

@@ -0,0 +1,81 @@
+" Author: Joshua Rubin <joshua@rubixconsulting.com>, Ben Reedy <https://github.com/breed808>,
+" Jeff Willette <jrwillette88@gmail.com>
+" Description: go build for Go files
+" inspired by work from dzhou121 <dzhou121@gmail.com>
+
+call ale#Set('go_gobuild_options', '')
+
+function! ale_linters#go#gobuild#ResetEnv() abort
+    unlet! s:go_env
+endfunction
+
+function! ale_linters#go#gobuild#GoEnv(buffer) abort
+    if exists('s:go_env')
+        return ''
+    endif
+
+    return 'go env GOPATH GOROOT'
+endfunction
+
+function! ale_linters#go#gobuild#GetCommand(buffer, goenv_output) abort
+    let l:options = ale#Var(a:buffer, 'go_gobuild_options')
+
+    if !exists('s:go_env')
+        let s:go_env = {
+        \   'GOPATH': a:goenv_output[0],
+        \   'GOROOT': a:goenv_output[1],
+        \}
+    endif
+
+    let l:gopath_env_command = has('win32')
+    \   ? 'set GOPATH=' . ale#Escape(s:go_env.GOPATH) . ' && '
+    \   : 'GOPATH=' . ale#Escape(s:go_env.GOPATH) . ' '
+
+    " Run go test in local directory with relative path
+    return l:gopath_env_command
+    \   . ale#path#BufferCdString(a:buffer)
+    \   . 'go test'
+    \   . (!empty(l:options) ? ' ' . l:options : '')
+    \   . ' -c -o /dev/null ./'
+endfunction
+
+function! ale_linters#go#gobuild#GetMatches(lines) abort
+    " Matches patterns like the following:
+    "
+    " file.go:27: missing argument for Printf("%s"): format reads arg 2, have only 1 args
+    " file.go:53:10: if block ends with a return statement, so drop this else and outdent its block (move short variable declaration to its own line if necessary)
+    " file.go:5:2: expected declaration, found 'STRING' "log"
+
+    " go test returns relative paths so use tail of filename as part of pattern matcher
+    let l:pattern = '\v^([a-zA-Z]?:?[^:]+):(\d+):?(\d+)?:? (.+)$'
+
+    return ale#util#GetMatches(a:lines, l:pattern)
+endfunction
+
+function! ale_linters#go#gobuild#Handler(buffer, lines) abort
+    let l:dir = expand('#' . a:buffer . ':p:h')
+    let l:output = []
+
+    for l:match in ale_linters#go#gobuild#GetMatches(a:lines)
+        call add(l:output, {
+        \   'filename': ale#path#GetAbsPath(l:dir, l:match[1]),
+        \   'lnum': l:match[2] + 0,
+        \   'col': l:match[3] + 0,
+        \   'text': l:match[4],
+        \   'type': 'E',
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('go', {
+\   'name': 'go build',
+\   'executable': 'go',
+\   'command_chain': [
+\     {'callback': 'ale_linters#go#gobuild#GoEnv', 'output_stream': 'stdout'},
+\     {'callback': 'ale_linters#go#gobuild#GetCommand', 'output_stream': 'stderr'},
+\   ],
+\   'callback': 'ale_linters#go#gobuild#Handler',
+\   'lint_file': 1,
+\})

sources_non_forked/ale/ale_linters/go/gofmt.vim

@@ -0,0 +1,10 @@
+" Author: neersighted <bjorn@neersighted.com>
+" Description: gofmt for Go files
+
+call ale#linter#Define('go', {
+\   'name': 'gofmt',
+\   'output_stream': 'stderr',
+\   'executable': 'gofmt',
+\   'command': 'gofmt -e %t',
+\   'callback': 'ale#handlers#unix#HandleAsError',
+\})

sources_non_forked/ale/ale_linters/go/golint.vim

@@ -0,0 +1,10 @@
+" Author: neersighted <bjorn@neersighted.com>
+" Description: golint for Go files
+
+call ale#linter#Define('go', {
+\   'name': 'golint',
+\   'output_stream': 'both',
+\   'executable': 'golint',
+\   'command': 'golint %t',
+\   'callback': 'ale#handlers#unix#HandleAsWarning',
+\})

sources_non_forked/ale/ale_linters/go/gometalinter.vim

@@ -0,0 +1,62 @@
+" Author: Ben Reedy <https://github.com/breed808>, Jeff Willette <jrwillette88@gmail.com>
+" Description: Adds support for the gometalinter suite for Go files
+
+call ale#Set('go_gometalinter_options', '')
+call ale#Set('go_gometalinter_executable', 'gometalinter')
+call ale#Set('go_gometalinter_lint_package', 0)
+
+function! ale_linters#go#gometalinter#GetExecutable(buffer) abort
+    return ale#Var(a:buffer, 'go_gometalinter_executable')
+endfunction
+
+function! ale_linters#go#gometalinter#GetCommand(buffer) abort
+    let l:executable = ale_linters#go#gometalinter#GetExecutable(a:buffer)
+    let l:filename = expand('#' . a:buffer . ':t')
+    let l:options = ale#Var(a:buffer, 'go_gometalinter_options')
+    let l:lint_package = ale#Var(a:buffer, 'go_gometalinter_lint_package')
+
+    " BufferCdString is used so that we can be sure the paths output from gometalinter can
+    " be calculated to absolute paths in the Handler
+    if l:lint_package
+        return ale#path#BufferCdString(a:buffer)
+        \   . ale#Escape(l:executable)
+        \   . (!empty(l:options) ? ' ' . l:options : '') . ' .'
+    endif
+
+    return ale#path#BufferCdString(a:buffer)
+    \   . ale#Escape(l:executable)
+    \   . ' --include=' . ale#Escape(ale#util#EscapePCRE(l:filename))
+    \   . (!empty(l:options) ? ' ' . l:options : '') . ' .'
+endfunction
+
+function! ale_linters#go#gometalinter#GetMatches(lines) abort
+    let l:pattern = '\v^([a-zA-Z]?:?[^:]+):(\d+):?(\d+)?:?:?(warning|error):?\s\*?(.+)$'
+
+    return ale#util#GetMatches(a:lines, l:pattern)
+endfunction
+
+function! ale_linters#go#gometalinter#Handler(buffer, lines) abort
+    let l:dir = expand('#' . a:buffer . ':p:h')
+    let l:output = []
+
+    for l:match in ale_linters#go#gometalinter#GetMatches(a:lines)
+        " l:match[1] will already be an absolute path, output from gometalinter
+        call add(l:output, {
+        \   'filename': ale#path#GetAbsPath(l:dir, l:match[1]),
+        \   'lnum': l:match[2] + 0,
+        \   'col': l:match[3] + 0,
+        \   'type': tolower(l:match[4]) is# 'warning' ? 'W' : 'E',
+        \   'text': l:match[5],
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('go', {
+\   'name': 'gometalinter',
+\   'executable_callback': 'ale_linters#go#gometalinter#GetExecutable',
+\   'command_callback': 'ale_linters#go#gometalinter#GetCommand',
+\   'callback': 'ale_linters#go#gometalinter#Handler',
+\   'lint_file': 1,
+\})

sources_non_forked/ale/ale_linters/go/gosimple.vim

@@ -0,0 +1,15 @@
+" Author: Ben Reedy <https://github.com/breed808>
+" Description: gosimple for Go files
+
+function! ale_linters#go#gosimple#GetCommand(buffer) abort
+    return ale#path#BufferCdString(a:buffer) . ' gosimple .'
+endfunction
+
+call ale#linter#Define('go', {
+\   'name': 'gosimple',
+\   'executable': 'gosimple',
+\   'command_callback': 'ale_linters#go#gosimple#GetCommand',
+\   'callback': 'ale#handlers#go#Handler',
+\   'output_stream': 'both',
+\   'lint_file': 1,
+\})

sources_non_forked/ale/ale_linters/go/gotype.vim

@@ -0,0 +1,20 @@
+" Author: Jelte Fennema <github-public@jeltef.nl>
+" Description: gotype for Go files
+
+function! ale_linters#go#gotype#GetCommand(buffer) abort
+    if expand('#' . a:buffer . ':p') =~# '_test\.go$'
+        return
+    endif
+
+
+    return ale#path#BufferCdString(a:buffer) . ' gotype .'
+endfunction
+
+call ale#linter#Define('go', {
+\   'name': 'gotype',
+\   'output_stream': 'stderr',
+\   'executable': 'gotype',
+\   'command_callback': 'ale_linters#go#gotype#GetCommand',
+\   'callback': 'ale#handlers#go#Handler',
+\   'lint_file': 1,
+\})

sources_non_forked/ale/ale_linters/go/govet.vim

@@ -0,0 +1,18 @@
+" Author: neersighted <bjorn@neersighted.com>
+" Description: go vet for Go files
+"
+" Author: John Eikenberry <jae@zhar.net>
+" Description: updated to work with go1.10
+
+function! ale_linters#go#govet#GetCommand(buffer) abort
+    return ale#path#BufferCdString(a:buffer) . ' go vet .'
+endfunction
+
+call ale#linter#Define('go', {
+\   'name': 'go vet',
+\   'output_stream': 'stderr',
+\   'executable': 'go',
+\   'command_callback': 'ale_linters#go#govet#GetCommand',
+\   'callback': 'ale#handlers#go#Handler',
+\   'lint_file': 1,
+\})

sources_non_forked/ale/ale_linters/go/staticcheck.vim

@@ -0,0 +1,33 @@
+" Author: Ben Reedy <https://github.com/breed808>
+" Description: staticcheck for Go files
+
+call ale#Set('go_staticcheck_options', '')
+call ale#Set('go_staticcheck_lint_package', 0)
+
+function! ale_linters#go#staticcheck#GetCommand(buffer) abort
+    let l:filename = expand('#' . a:buffer . ':t')
+    let l:options = ale#Var(a:buffer, 'go_staticcheck_options')
+    let l:lint_package = ale#Var(a:buffer, 'go_staticcheck_lint_package')
+
+    " BufferCdString is used so that we can be sure the paths output from
+    " staticcheck can be calculated to absolute paths in the Handler
+    if l:lint_package
+        return ale#path#BufferCdString(a:buffer)
+        \   . 'staticcheck'
+        \   . (!empty(l:options) ? ' ' . l:options : '') . ' .'
+    endif
+
+    return ale#path#BufferCdString(a:buffer)
+    \   . 'staticcheck'
+    \   . (!empty(l:options) ? ' ' . l:options : '')
+    \   . ' ' . ale#Escape(l:filename)
+endfunction
+
+call ale#linter#Define('go', {
+\   'name': 'staticcheck',
+\   'executable': 'staticcheck',
+\   'command_callback': 'ale_linters#go#staticcheck#GetCommand',
+\   'callback': 'ale#handlers#go#Handler',
+\   'output_stream': 'both',
+\   'lint_file': 1,
+\})