Removed syntastic and replaced it with ale

Read more here:
https://github.com/w0rp/ale

sources_non_forked/ale/ale_linters/javascript/eslint.vim

@@ -0,0 +1,10 @@
+" Author: w0rp <devw0rp@gmail.com>
+" Description: eslint for JavaScript files
+
+call ale#linter#Define('javascript', {
+\   'name': 'eslint',
+\   'output_stream': 'both',
+\   'executable_callback': 'ale#handlers#eslint#GetExecutable',
+\   'command_callback': 'ale#handlers#eslint#GetCommand',
+\   'callback': 'ale#handlers#eslint#Handle',
+\})

sources_non_forked/ale/ale_linters/javascript/flow.vim

@@ -0,0 +1,178 @@
+" Author: Zach Perrault -- @zperrault
+" Author: Florian Beeres <yuuki@protonmail.com>
+" Description: FlowType checking for JavaScript files
+
+call ale#Set('javascript_flow_executable', 'flow')
+call ale#Set('javascript_flow_use_home_config', 0)
+call ale#Set('javascript_flow_use_global', 0)
+
+function! ale_linters#javascript#flow#GetExecutable(buffer) abort
+    let l:flow_config = ale#path#FindNearestFile(a:buffer, '.flowconfig')
+
+    if empty(l:flow_config)
+        " Don't run Flow if we can't find a .flowconfig file.
+        return ''
+    endif
+
+    " Don't run Flow with a configuration file from the home directory by
+    " default, which can eat all of your RAM.
+    if fnamemodify(l:flow_config, ':h') is? $HOME
+    \&& !ale#Var(a:buffer, 'javascript_flow_use_home_config')
+        return ''
+    endif
+
+    return ale#node#FindExecutable(a:buffer, 'javascript_flow', [
+    \   'node_modules/.bin/flow',
+    \])
+endfunction
+
+function! ale_linters#javascript#flow#VersionCheck(buffer) abort
+    let l:executable = ale_linters#javascript#flow#GetExecutable(a:buffer)
+
+    if empty(l:executable)
+        return ''
+    endif
+
+    return ale#Escape(l:executable) . ' --version'
+endfunction
+
+function! ale_linters#javascript#flow#GetCommand(buffer, version_lines) abort
+    let l:executable = ale_linters#javascript#flow#GetExecutable(a:buffer)
+
+    if empty(l:executable)
+        return ''
+    endif
+
+    let l:version = ale#semver#GetVersion(l:executable, a:version_lines)
+
+    " If we can parse the version number, then only use --respect-pragma
+    " if the version is >= 0.36.0, which added the argument.
+    let l:use_respect_pragma = empty(l:version)
+    \   || ale#semver#GTE(l:version, [0, 36])
+
+    return ale#Escape(l:executable)
+    \   . ' check-contents'
+    \   . (l:use_respect_pragma ? ' --respect-pragma': '')
+    \   . ' --json --from ale %s'
+endfunction
+
+" Filter lines of flow output until we find the first line where the JSON
+" output starts.
+function! s:GetJSONLines(lines) abort
+    let l:start_index = 0
+
+    for l:line in a:lines
+        if l:line[:0] is# '{'
+            break
+        endif
+
+        let l:start_index += 1
+    endfor
+
+    return a:lines[l:start_index :]
+endfunction
+
+function! s:ExtraErrorMsg(current, new) abort
+    let l:newMsg = ''
+
+    if a:current is# ''
+        " extra messages appear to already have a :
+        let l:newMsg = a:new
+    else
+        let l:newMsg = a:current . ' ' . a:new
+    endif
+
+    return l:newMsg
+endfunction
+
+
+function! s:GetDetails(error) abort
+    let l:detail = ''
+
+    for l:extra_error in a:error.extra
+
+        if has_key(l:extra_error, 'message')
+            for l:extra_message in l:extra_error.message
+                let l:detail = s:ExtraErrorMsg(l:detail, l:extra_message.descr)
+            endfor
+        endif
+
+        if has_key(l:extra_error, 'children')
+            for l:child in l:extra_error.children
+                for l:child_message in l:child.message
+                    let l:detail = l:detail . ' ' . l:child_message.descr
+                endfor
+            endfor
+        endif
+
+    endfor
+
+    return l:detail
+endfunction
+
+function! ale_linters#javascript#flow#Handle(buffer, lines) abort
+    let l:str = join(s:GetJSONLines(a:lines), '')
+
+    if empty(l:str)
+        return []
+    endif
+
+    let l:flow_output = json_decode(l:str)
+    let l:output = []
+
+    for l:error in get(l:flow_output, 'errors', [])
+        " Each error is broken up into parts
+        let l:text = ''
+        let l:line = 0
+        let l:col = 0
+
+        for l:message in l:error.message
+            " Comments have no line of column information, so we skip them.
+            " In certain cases, `l:message.loc.source` points to a different path
+            " than the buffer one, thus we skip this loc information too.
+            if has_key(l:message, 'loc')
+            \&& l:line is# 0
+            \&& ale#path#IsBufferPath(a:buffer, l:message.loc.source)
+                let l:line = l:message.loc.start.line + 0
+                let l:col = l:message.loc.start.column + 0
+            endif
+
+            if l:text is# ''
+                let l:text = l:message.descr . ':'
+            else
+                let l:text = l:text . ' ' . l:message.descr
+            endif
+        endfor
+
+        if has_key(l:error, 'operation')
+            let l:text = l:text . ' See also: ' . l:error.operation.descr
+        endif
+
+        let l:errorToAdd = {
+        \   'lnum': l:line,
+        \   'col': l:col,
+        \   'text': l:text,
+        \   'type': has_key(l:error, 'level') && l:error.level is# 'error' ? 'E' : 'W',
+        \}
+
+        if has_key(l:error, 'extra')
+            let l:errorToAdd.detail = s:GetDetails(l:error)
+        endif
+
+        call add(l:output, l:errorToAdd)
+
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('javascript', {
+\   'name': 'flow',
+\   'executable_callback': 'ale_linters#javascript#flow#GetExecutable',
+\   'command_chain': [
+\       {'callback': 'ale_linters#javascript#flow#VersionCheck'},
+\       {'callback': 'ale_linters#javascript#flow#GetCommand'},
+\   ],
+\   'callback': 'ale_linters#javascript#flow#Handle',
+\   'add_newline': !has('win32'),
+\})

sources_non_forked/ale/ale_linters/javascript/jscs.vim

@@ -0,0 +1,67 @@
+" Author: Chris Kyrouac - https://github.com/fijshion
+" Description: jscs for JavaScript files
+
+call ale#Set('javascript_jscs_executable', 'jscs')
+call ale#Set('javascript_jscs_use_global', 0)
+
+function! ale_linters#javascript#jscs#GetExecutable(buffer) abort
+    return ale#node#FindExecutable(a:buffer, 'javascript_jscs', [
+    \   'node_modules/.bin/jscs',
+    \])
+endfunction
+
+function! ale_linters#javascript#jscs#GetCommand(buffer) abort
+    " Search for a local JShint config locaation, and default to a global one.
+    let l:jscs_config = ale#path#ResolveLocalPath(
+    \   a:buffer,
+    \   '.jscsrc',
+    \   get(g:, 'ale_jscs_config_loc', '')
+    \)
+
+    let l:command = ale#Escape(ale_linters#javascript#jscs#GetExecutable(a:buffer))
+    let l:command .= ' --reporter inline --no-colors'
+
+    if !empty(l:jscs_config)
+        let l:command .= ' --config ' . ale#Escape(l:jscs_config)
+    endif
+
+    let l:command .= ' -'
+
+    return l:command
+endfunction
+
+function! ale_linters#javascript#jscs#Handle(buffer, lines) abort
+    " Matches patterns looking like the following
+    "
+    " foobar.js: line 2, col 1, Expected indentation of 1 characters
+    "
+    let l:pattern = '\v^.*:\s+line (\d+),\s+col\s+(\d+),\s+(.*)$'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        let l:obj = {
+        \   'lnum': l:match[1] + 0,
+        \   'col': l:match[2] + 0,
+        \   'text': l:match[3]
+        \}
+
+        let l:code_match = matchlist(l:match[3], '\v([^ :]+): (.+)$')
+
+        if !empty(l:code_match)
+            let l:obj.code = l:code_match[1]
+            let l:obj.text = l:code_match[2]
+        endif
+
+        call add(l:output, l:obj)
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('javascript', {
+\   'name': 'jscs',
+\   'executable_callback': 'ale_linters#javascript#jscs#GetExecutable',
+\   'command_callback': 'ale_linters#javascript#jscs#GetCommand',
+\   'callback': 'ale_linters#javascript#jscs#Handle',
+\})
+

sources_non_forked/ale/ale_linters/javascript/jshint.vim

@@ -0,0 +1,38 @@
+" Author: Chris Kyrouac - https://github.com/fijshion
+" Description: JSHint for Javascript files
+
+call ale#Set('javascript_jshint_executable', 'jshint')
+call ale#Set('javascript_jshint_use_global', 0)
+
+function! ale_linters#javascript#jshint#GetExecutable(buffer) abort
+    return ale#node#FindExecutable(a:buffer, 'javascript_jshint', [
+    \   'node_modules/.bin/jshint',
+    \])
+endfunction
+
+function! ale_linters#javascript#jshint#GetCommand(buffer) abort
+    " Search for a local JShint config locaation, and default to a global one.
+    let l:jshint_config = ale#path#ResolveLocalPath(
+    \   a:buffer,
+    \   '.jshintrc',
+    \   get(g:, 'ale_jshint_config_loc', '')
+    \)
+
+    let l:command = ale#Escape(ale_linters#javascript#jshint#GetExecutable(a:buffer))
+    let l:command .= ' --reporter unix --extract auto'
+
+    if !empty(l:jshint_config)
+        let l:command .= ' --config ' . ale#Escape(l:jshint_config)
+    endif
+
+    let l:command .= ' -'
+
+    return l:command
+endfunction
+
+call ale#linter#Define('javascript', {
+\   'name': 'jshint',
+\   'executable_callback': 'ale_linters#javascript#jshint#GetExecutable',
+\   'command_callback': 'ale_linters#javascript#jshint#GetCommand',
+\   'callback': 'ale#handlers#unix#HandleAsError',
+\})

sources_non_forked/ale/ale_linters/javascript/standard.vim

@@ -0,0 +1,30 @@
+" Author: Ahmed El Gabri <@ahmedelgabri>
+" Description: standardjs for JavaScript files
+
+call ale#Set('javascript_standard_executable', 'standard')
+call ale#Set('javascript_standard_use_global', 0)
+call ale#Set('javascript_standard_options', '')
+
+function! ale_linters#javascript#standard#GetExecutable(buffer) abort
+    return ale#node#FindExecutable(a:buffer, 'javascript_standard', [
+    \   'node_modules/standard/bin/cmd.js',
+    \   'node_modules/.bin/standard',
+    \])
+endfunction
+
+function! ale_linters#javascript#standard#GetCommand(buffer) abort
+    let l:executable = ale_linters#javascript#standard#GetExecutable(a:buffer)
+    let l:options = ale#Var(a:buffer, 'javascript_standard_options')
+
+    return ale#node#Executable(a:buffer, l:executable)
+    \   . (!empty(l:options) ? ' ' . l:options : '')
+    \   . ' --stdin %s'
+endfunction
+
+" standard uses eslint and the output format is the same
+call ale#linter#Define('javascript', {
+\   'name': 'standard',
+\   'executable_callback': 'ale_linters#javascript#standard#GetExecutable',
+\   'command_callback': 'ale_linters#javascript#standard#GetCommand',
+\   'callback': 'ale#handlers#eslint#Handle',
+\})

sources_non_forked/ale/ale_linters/javascript/xo.vim

@@ -0,0 +1,26 @@
+" Author: Daniel Lupu <lupu.daniel.f@gmail.com>
+" Description: xo for JavaScript files
+
+call ale#Set('javascript_xo_executable', 'xo')
+call ale#Set('javascript_xo_use_global', 0)
+call ale#Set('javascript_xo_options', '')
+
+function! ale_linters#javascript#xo#GetExecutable(buffer) abort
+    return ale#node#FindExecutable(a:buffer, 'javascript_xo', [
+    \   'node_modules/.bin/xo',
+    \])
+endfunction
+
+function! ale_linters#javascript#xo#GetCommand(buffer) abort
+    return ale#Escape(ale_linters#javascript#xo#GetExecutable(a:buffer))
+    \   . ' ' . ale#Var(a:buffer, 'javascript_xo_options')
+    \   . ' --reporter unix --stdin --stdin-filename %s'
+endfunction
+
+" xo uses eslint and the output format is the same
+call ale#linter#Define('javascript', {
+\   'name': 'xo',
+\   'executable_callback': 'ale_linters#javascript#xo#GetExecutable',
+\   'command_callback': 'ale_linters#javascript#xo#GetCommand',
+\   'callback': 'ale#handlers#eslint#Handle',
+\})