Removed syntastic and replaced it with ale

Read more here:
https://github.com/w0rp/ale

sources_non_forked/ale/ale_linters/ruby/brakeman.vim

@@ -0,0 +1,47 @@
+" Author: Eddie Lebow https://github.com/elebow
+" Description: Brakeman, a static analyzer for Rails security
+
+let g:ale_ruby_brakeman_options =
+\   get(g:, 'ale_ruby_brakeman_options', '')
+
+function! ale_linters#ruby#brakeman#Handle(buffer, lines) abort
+    let l:output = []
+    let l:json = ale#util#FuzzyJSONDecode(a:lines, {})
+    let l:sep = has('win32') ? '\' : '/'
+    " Brakeman always outputs paths relative to the Rails app root
+    let l:rails_root = ale#ruby#FindRailsRoot(a:buffer)
+
+    for l:warning in get(l:json, 'warnings', [])
+        let l:text = l:warning.warning_type . ' ' . l:warning.message . ' (' . l:warning.confidence . ')'
+        let l:line = l:warning.line != v:null ? l:warning.line : 1
+
+        call add(l:output, {
+        \   'filename': l:rails_root . l:sep .  l:warning.file,
+        \   'lnum': l:line,
+        \   'type': 'W',
+        \   'text': l:text,
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+function! ale_linters#ruby#brakeman#GetCommand(buffer) abort
+    let l:rails_root = ale#ruby#FindRailsRoot(a:buffer)
+
+    if l:rails_root is? ''
+        return ''
+    endif
+
+    return 'brakeman -f json -q '
+    \    . ale#Var(a:buffer, 'ruby_brakeman_options')
+    \    . ' -p ' . ale#Escape(l:rails_root)
+endfunction
+
+call ale#linter#Define('ruby', {
+\    'name': 'brakeman',
+\    'executable': 'brakeman',
+\    'command_callback': 'ale_linters#ruby#brakeman#GetCommand',
+\    'callback': 'ale_linters#ruby#brakeman#Handle',
+\    'lint_file': 1,
+\})

sources_non_forked/ale/ale_linters/ruby/rails_best_practices.vim

@@ -0,0 +1,53 @@
+" Author: Eddie Lebow https://github.com/elebow
+" Description: rails_best_practices, a code metric tool for rails projects
+
+let g:ale_ruby_rails_best_practices_options =
+\   get(g:, 'ale_ruby_rails_best_practices_options', '')
+
+function! ale_linters#ruby#rails_best_practices#Handle(buffer, lines) abort
+    let l:output = []
+
+    for l:warning in ale#util#FuzzyJSONDecode(a:lines, [])
+        if !ale#path#IsBufferPath(a:buffer, l:warning.filename)
+            continue
+        endif
+
+        call add(l:output, {
+        \    'lnum': l:warning.line_number + 0,
+        \    'type': 'W',
+        \    'text': l:warning.message,
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+function! ale_linters#ruby#rails_best_practices#GetCommand(buffer) abort
+    let l:executable = ale#handlers#rails_best_practices#GetExecutable(a:buffer)
+    let l:exec_args = l:executable =~? 'bundle$'
+    \   ? ' exec rails_best_practices'
+    \   : ''
+
+    let l:rails_root = ale#ruby#FindRailsRoot(a:buffer)
+
+    if l:rails_root is? ''
+        return ''
+    endif
+
+    let l:output_file = ale#Has('win32') ? '%t ' : '/dev/stdout '
+    let l:cat_file = ale#Has('win32') ? '; type %t' : ''
+
+    return ale#Escape(l:executable) . l:exec_args
+    \    . ' --silent -f json --output-file ' . l:output_file
+    \    . ale#Var(a:buffer, 'ruby_rails_best_practices_options')
+    \    . ale#Escape(l:rails_root)
+    \    . l:cat_file
+endfunction
+
+call ale#linter#Define('ruby', {
+\    'name': 'rails_best_practices',
+\    'executable_callback': 'ale#handlers#rails_best_practices#GetExecutable',
+\    'command_callback': 'ale_linters#ruby#rails_best_practices#GetCommand',
+\    'callback': 'ale_linters#ruby#rails_best_practices#Handle',
+\    'lint_file': 1,
+\})

sources_non_forked/ale/ale_linters/ruby/reek.vim

@@ -0,0 +1,45 @@
+" Author: Eddie Lebow https://github.com/elebow
+" Description: Reek, a code smell detector for Ruby files
+
+call ale#Set('ruby_reek_show_context', 0)
+call ale#Set('ruby_reek_show_wiki_link', 0)
+
+function! ale_linters#ruby#reek#Handle(buffer, lines) abort
+    let l:output = []
+
+    for l:error in ale#util#FuzzyJSONDecode(a:lines, [])
+        for l:location in l:error.lines
+            call add(l:output, {
+            \    'lnum': l:location,
+            \    'type': 'W',
+            \    'text': s:BuildText(a:buffer, l:error),
+            \    'code': l:error.smell_type,
+            \})
+        endfor
+    endfor
+
+    return l:output
+endfunction
+
+function! s:BuildText(buffer, error) abort
+    let l:parts = []
+
+    if ale#Var(a:buffer, 'ruby_reek_show_context')
+        call add(l:parts, a:error.context)
+    endif
+
+    call add(l:parts, a:error.message)
+
+    if ale#Var(a:buffer, 'ruby_reek_show_wiki_link')
+        call add(l:parts, '[' . a:error.wiki_link . ']')
+    endif
+
+    return join(l:parts, ' ')
+endfunction
+
+call ale#linter#Define('ruby', {
+\    'name': 'reek',
+\    'executable': 'reek',
+\    'command': 'reek -f json --no-progress --no-color',
+\    'callback': 'ale_linters#ruby#reek#Handle',
+\})

sources_non_forked/ale/ale_linters/ruby/rubocop.vim

@@ -0,0 +1,61 @@
+" Author: ynonp - https://github.com/ynonp, Eddie Lebow https://github.com/elebow
+" Description: RuboCop, a code style analyzer for Ruby files
+
+function! ale_linters#ruby#rubocop#GetCommand(buffer) abort
+    let l:executable = ale#handlers#rubocop#GetExecutable(a:buffer)
+    let l:exec_args = l:executable =~? 'bundle$'
+    \   ? ' exec rubocop'
+    \   : ''
+
+    return ale#Escape(l:executable) . l:exec_args
+    \   . ' --format json --force-exclusion '
+    \   . ale#Var(a:buffer, 'ruby_rubocop_options')
+    \   . ' --stdin ' . ale#Escape(expand('#' . a:buffer . ':p'))
+endfunction
+
+function! ale_linters#ruby#rubocop#Handle(buffer, lines) abort
+    try
+        let l:errors = json_decode(a:lines[0])
+    catch
+        return []
+    endtry
+
+    if !has_key(l:errors, 'summary')
+    \|| l:errors['summary']['offense_count'] == 0
+    \|| empty(l:errors['files'])
+        return []
+    endif
+
+    let l:output = []
+
+    for l:error in l:errors['files'][0]['offenses']
+        let l:start_col = l:error['location']['column'] + 0
+        call add(l:output, {
+        \   'lnum': l:error['location']['line'] + 0,
+        \   'col': l:start_col,
+        \   'end_col': l:start_col + l:error['location']['length'] - 1,
+        \   'code': l:error['cop_name'],
+        \   'text': l:error['message'],
+        \   'type': ale_linters#ruby#rubocop#GetType(l:error['severity']),
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+function! ale_linters#ruby#rubocop#GetType(severity) abort
+    if a:severity is? 'convention'
+    \|| a:severity is? 'warning'
+    \|| a:severity is? 'refactor'
+        return 'W'
+    endif
+
+    return 'E'
+endfunction
+
+call ale#linter#Define('ruby', {
+\   'name': 'rubocop',
+\   'executable_callback': 'ale#handlers#rubocop#GetExecutable',
+\   'command_callback': 'ale_linters#ruby#rubocop#GetCommand',
+\   'callback': 'ale_linters#ruby#rubocop#Handle',
+\})

sources_non_forked/ale/ale_linters/ruby/ruby.vim

@@ -0,0 +1,22 @@
+" Author: Brandon Roehl - https://github.com/BrandonRoehl
+" Description: Ruby MRI for Ruby files
+
+call ale#Set('ruby_ruby_executable', 'ruby')
+
+function! ale_linters#ruby#ruby#GetExecutable(buffer) abort
+    return ale#Var(a:buffer, 'ruby_ruby_executable')
+endfunction
+
+function! ale_linters#ruby#ruby#GetCommand(buffer) abort
+    let l:executable = ale_linters#ruby#ruby#GetExecutable(a:buffer)
+
+    return ale#Escape(l:executable) . ' -w -c -T1 %t'
+endfunction
+
+call ale#linter#Define('ruby', {
+\   'name': 'ruby',
+\   'executable_callback': 'ale_linters#ruby#ruby#GetExecutable',
+\   'command_callback': 'ale_linters#ruby#ruby#GetCommand',
+\   'output_stream': 'stderr',
+\   'callback': 'ale#handlers#ruby#HandleSyntaxErrors',
+\})