Removed syntastic and replaced it with ale

Read more here:
https://github.com/w0rp/ale

sources_non_forked/ale/ale_linters/scss/sasslint.vim

@@ -0,0 +1,8 @@
+" Author: KabbAmine - https://github.com/KabbAmine
+
+call ale#linter#Define('scss', {
+\   'name': 'sasslint',
+\   'executable': 'sass-lint',
+\   'command': 'sass-lint -v -q -f compact %t',
+\   'callback': 'ale#handlers#css#HandleCSSLintFormat',
+\})

sources_non_forked/ale/ale_linters/scss/scsslint.vim

@@ -0,0 +1,34 @@
+" Author: w0rp <devw0rp@gmail.com>
+" Description: This file add scsslint support for SCSS support
+
+function! ale_linters#scss#scsslint#Handle(buffer, lines) abort
+    " Matches patterns like the following:
+    "
+    " test.scss:2:1 [W] Indentation: Line should be indented 2 spaces, but was indented 4 spaces
+    let l:pattern = '^.*:\(\d\+\):\(\d*\) \[\([^\]]\+\)\] \(.\+\)$'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        if !ale#Var(a:buffer, 'warn_about_trailing_whitespace')
+        \&& l:match[4] =~# '^TrailingWhitespace'
+            " Skip trailing whitespace warnings if that option is off.
+            continue
+        endif
+
+        call add(l:output, {
+        \   'lnum': l:match[1] + 0,
+        \   'col': l:match[2] + 0,
+        \   'text': l:match[4],
+        \   'type': l:match[3] is# 'E' ? 'E' : 'W',
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('scss', {
+\   'name': 'scsslint',
+\   'executable': 'scss-lint',
+\   'command': 'scss-lint --stdin-file-path=%s',
+\   'callback': 'ale_linters#scss#scsslint#Handle',
+\})

sources_non_forked/ale/ale_linters/scss/stylelint.vim

@@ -0,0 +1,22 @@
+" Author: diartyz <diartyz@gmail.com>
+
+call ale#Set('scss_stylelint_executable', 'stylelint')
+call ale#Set('scss_stylelint_use_global', 0)
+
+function! ale_linters#scss#stylelint#GetExecutable(buffer) abort
+    return ale#node#FindExecutable(a:buffer, 'scss_stylelint', [
+    \   'node_modules/.bin/stylelint',
+    \])
+endfunction
+
+function! ale_linters#scss#stylelint#GetCommand(buffer) abort
+    return ale_linters#scss#stylelint#GetExecutable(a:buffer)
+    \   . ' --stdin-filename %s'
+endfunction
+
+call ale#linter#Define('scss', {
+\   'name': 'stylelint',
+\   'executable_callback': 'ale_linters#scss#stylelint#GetExecutable',
+\   'command_callback': 'ale_linters#scss#stylelint#GetCommand',
+\   'callback': 'ale#handlers#css#HandleStyleLintFormat',
+\})