Updated plugins

sources_non_forked/ale/ale_linters/python/flake8.vim

@@ -4,7 +4,7 @@
 call ale#Set('python_flake8_executable', 'flake8')
 call ale#Set('python_flake8_options', '')
 call ale#Set('python_flake8_use_global', get(g:, 'ale_use_global_executables', 0))
-call ale#Set('python_flake8_change_directory', 1)
+call ale#Set('python_flake8_change_directory', 'project')
 call ale#Set('python_flake8_auto_pipenv', 0)
 
 function! s:UsingModule(buffer) abort
@@ -38,10 +38,30 @@ function! ale_linters#python#flake8#RunWithVersionCheck(buffer) abort
     \)
 endfunction
 
+function! ale_linters#python#flake8#GetCdString(buffer) abort
+    let l:change_directory = ale#Var(a:buffer, 'python_flake8_change_directory')
+    let l:cd_string = ''
+
+    if l:change_directory is# 'project'
+        let l:project_root = ale#python#FindProjectRootIni(a:buffer)
+
+        if !empty(l:project_root)
+            let l:cd_string = ale#path#CdString(l:project_root)
+        endif
+    endif
+
+    if (l:change_directory is# 'project' && empty(l:cd_string))
+    \|| l:change_directory is# 1
+    \|| l:change_directory is# 'file'
+        let l:cd_string = ale#path#BufferCdString(a:buffer)
+    endif
+
+    return l:cd_string
+endfunction
+
 function! ale_linters#python#flake8#GetCommand(buffer, version) abort
-    let l:cd_string = ale#Var(a:buffer, 'python_flake8_change_directory')
-    \   ? ale#path#BufferCdString(a:buffer)
-    \   : ''
+    let l:cd_string = ale_linters#python#flake8#GetCdString(a:buffer)
+
     let l:executable = ale_linters#python#flake8#GetExecutable(a:buffer)
 
     let l:exec_args = l:executable =~? 'pipenv$'

sources_non_forked/ale/ale_linters/python/jedils.vim

@@ -0,0 +1,34 @@
+" Author: Dalius Dobravolskas <dalius.dobravolskas@gmail.com>
+" Description: https://github.com/pappasam/jedi-language-server
+
+call ale#Set('python_jedils_executable', 'jedi-language-server')
+call ale#Set('python_jedils_use_global', get(g:, 'ale_use_global_executables', 0))
+call ale#Set('python_jedils_auto_pipenv', 0)
+
+function! ale_linters#python#jedils#GetExecutable(buffer) abort
+    if (ale#Var(a:buffer, 'python_auto_pipenv') || ale#Var(a:buffer, 'python_jedils_auto_pipenv'))
+    \ && ale#python#PipenvPresent(a:buffer)
+        return 'pipenv'
+    endif
+
+    return ale#python#FindExecutable(a:buffer, 'python_jedils', ['jedi-language-server'])
+endfunction
+
+function! ale_linters#python#jedils#GetCommand(buffer) abort
+    let l:executable = ale_linters#python#jedils#GetExecutable(a:buffer)
+
+    let l:exec_args = l:executable =~? 'pipenv$'
+    \   ? ' run jedi-language-server'
+    \   : ''
+
+    return ale#Escape(l:executable) . l:exec_args
+endfunction
+
+call ale#linter#Define('python', {
+\   'name': 'jedils',
+\   'lsp': 'stdio',
+\   'executable': function('ale_linters#python#jedils#GetExecutable'),
+\   'command': function('ale_linters#python#jedils#GetCommand'),
+\   'project_root': function('ale#python#FindProjectRoot'),
+\   'completion_filter': 'ale#completion#python#CompletionItemFilter',
+\})

sources_non_forked/ale/ale_linters/python/pydocstyle.vim

@@ -16,17 +16,15 @@ function! ale_linters#python#pydocstyle#GetExecutable(buffer) abort
 endfunction
 
 function! ale_linters#python#pydocstyle#GetCommand(buffer) abort
-    let l:dir = fnamemodify(bufname(a:buffer), ':p:h')
     let l:executable = ale_linters#python#pydocstyle#GetExecutable(a:buffer)
-
     let l:exec_args = l:executable =~? 'pipenv$'
     \   ? ' run pydocstyle'
     \   : ''
 
-    return ale#path#CdString(l:dir)
+    return ale#path#BufferCdString(a:buffer)
     \   . ale#Escape(l:executable) . l:exec_args
-    \   . ' ' . ale#Var(a:buffer, 'python_pydocstyle_options')
-    \   . ' ' . ale#Escape(fnamemodify(bufname(a:buffer), ':p:t'))
+    \   . ale#Pad(ale#Var(a:buffer, 'python_pydocstyle_options'))
+    \   . ' %s:t'
 endfunction
 
 function! ale_linters#python#pydocstyle#Handle(buffer, lines) abort

sources_non_forked/ale/ale_linters/python/pylint.vim

@@ -17,7 +17,7 @@ function! ale_linters#python#pylint#GetExecutable(buffer) abort
     return ale#python#FindExecutable(a:buffer, 'python_pylint', ['pylint'])
 endfunction
 
-function! ale_linters#python#pylint#GetCommand(buffer) abort
+function! ale_linters#python#pylint#GetCommand(buffer, version) abort
     let l:cd_string = ''
 
     if ale#Var(a:buffer, 'python_pylint_change_directory')
@@ -38,17 +38,23 @@ function! ale_linters#python#pylint#GetCommand(buffer) abort
 
     return l:cd_string
     \   . ale#Escape(l:executable) . l:exec_args
-    \   . ' ' . ale#Var(a:buffer, 'python_pylint_options')
+    \   . ale#Pad(ale#Var(a:buffer, 'python_pylint_options'))
     \   . ' --output-format text --msg-template="{path}:{line}:{column}: {msg_id} ({symbol}) {msg}" --reports n'
+    \   .  (ale#semver#GTE(a:version, [2, 4, 0]) ? ' --from-stdin' : '')
     \   . ' %s'
 endfunction
 
 function! ale_linters#python#pylint#Handle(buffer, lines) abort
+    let l:output = ale#python#HandleTraceback(a:lines, 10)
+
+    if !empty(l:output)
+        return l:output
+    endif
+
     " Matches patterns like the following:
     "
     " test.py:4:4: W0101 (unreachable) Unreachable code
     let l:pattern = '\v^[a-zA-Z]?:?[^:]+:(\d+):(\d+): ([[:alnum:]]+) \(([^(]*)\) (.*)$'
-    let l:output = []
 
     for l:match in ale#util#GetMatches(a:lines, l:pattern)
         "let l:failed = append(0, l:match)
@@ -71,13 +77,19 @@ function! ale_linters#python#pylint#Handle(buffer, lines) abort
             let l:code_out = l:match[4]
         endif
 
-        call add(l:output, {
+        let l:item = {
         \   'lnum': l:match[1] + 0,
         \   'col': l:match[2] + 1,
         \   'text': l:match[5],
         \   'code': l:code_out,
-        \   'type': l:code[:0] is# 'E' ? 'E' : 'W',
-        \})
+        \   'type': 'W',
+        \}
+
+        if l:code[:0] is# 'E'
+            let l:item.type = 'E'
+        endif
+
+        call add(l:output, l:item)
     endfor
 
     return l:output
@@ -86,7 +98,17 @@ endfunction
 call ale#linter#Define('python', {
 \   'name': 'pylint',
 \   'executable': function('ale_linters#python#pylint#GetExecutable'),
-\   'command': function('ale_linters#python#pylint#GetCommand'),
+\   'lint_file': {buffer -> ale#semver#RunWithVersionCheck(
+\       buffer,
+\       ale#Var(buffer, 'python_pylint_executable'),
+\       '%e --version',
+\       {buffer, version -> !ale#semver#GTE(version, [2, 4, 0])},
+\   )},
+\   'command': {buffer -> ale#semver#RunWithVersionCheck(
+\       buffer,
+\       ale#Var(buffer, 'python_pylint_executable'),
+\       '%e --version',
+\       function('ale_linters#python#pylint#GetCommand'),
+\   )},
 \   'callback': 'ale_linters#python#pylint#Handle',
-\   'lint_file': 1,
 \})

sources_non_forked/ale/ale_linters/python/pyright.vim

@@ -0,0 +1,43 @@
+call ale#Set('python_pyright_executable', 'pyright-langserver')
+call ale#Set('python_pyright_config', {})
+
+function! ale_linters#python#pyright#GetConfig(buffer) abort
+    let l:config = deepcopy(ale#Var(a:buffer, 'python_pyright_config'))
+
+    if !has_key(l:config, 'python')
+        let l:config.python = {}
+    endif
+
+    if type(l:config.python) is v:t_dict
+        " Automatically detect the virtualenv path and use it.
+        if !has_key(l:config.python, 'venvPath')
+            let l:venv = ale#python#FindVirtualenv(a:buffer)
+
+            if !empty(l:venv)
+                let l:config.python.venvPath = l:venv
+            endif
+        endif
+
+        " Automatically use the version of Python in virtualenv.
+        if type(get(l:config.python, 'venvPath')) is v:t_string
+        \&& !empty(l:config.python.venvPath)
+        \&& !has_key(l:config.python, 'pythonPath')
+            let l:config.python.pythonPath = ale#path#Simplify(
+            \   l:config.python.venvPath
+            \   . (has('win32') ? '/Scripts/python' : '/bin/python')
+            \)
+        endif
+    endif
+
+    return l:config
+endfunction
+
+call ale#linter#Define('python', {
+\   'name': 'pyright',
+\   'lsp': 'stdio',
+\   'executable': {b -> ale#Var(b, 'python_pyright_executable')},
+\   'command': '%e --stdio',
+\   'project_root': function('ale#python#FindProjectRoot'),
+\   'completion_filter': 'ale#completion#python#CompletionItemFilter',
+\   'lsp_config': function('ale_linters#python#pyright#GetConfig'),
+\})