Updated plugins

sources_non_forked/ale/autoload/ale/fixers/alejandra.vim

@@ -0,0 +1,13 @@
+call ale#Set('nix_alejandra_executable', 'alejandra')
+call ale#Set('nix_alejandra_options', '')
+
+function! ale#fixers#alejandra#Fix(buffer) abort
+    let l:executable = ale#Var(a:buffer, 'nix_alejandra_executable')
+    let l:options = ale#Var(a:buffer, 'nix_alejandra_options')
+
+    return {
+    \   'command': ale#Escape(l:executable)
+    \       . (empty(l:options) ? '' : ' ' . l:options)
+    \       . ' -- -'
+    \}
+endfunction

sources_non_forked/ale/autoload/ale/fixers/gopls.vim

@@ -0,0 +1,23 @@
+" Author: Sean Enck <enckse@voidedtech.com>
+" Description: Integration of gopls format with ALE.
+
+call ale#Set('go_gopls_fix_executable', 'gopls')
+call ale#Set('go_gopls_fix_options', '')
+
+function! ale#fixers#gopls#Fix(buffer) abort
+    let l:executable = ale#Var(a:buffer, 'go_gopls_fix_executable')
+    let l:options = ale#Var(a:buffer, 'go_gopls_fix_options')
+    let l:env = ale#go#EnvString(a:buffer)
+
+    if !executable(l:executable)
+        return 0
+    endif
+
+    return {
+    \   'command': l:env . ale#Escape(l:executable)
+    \       . ' format'
+    \       . ale#Pad(l:options)
+    \       . ' -l -w %t',
+    \   'read_temporary_file': 1,
+    \}
+endfunction

sources_non_forked/ale/autoload/ale/fixers/pycln.vim

@@ -0,0 +1,90 @@
+" Author: Yining <zhang.yining@gmail.com>
+" Description: pycln as ALE fixer for python files
+
+call ale#Set('python_pycln_executable', 'pycln')
+call ale#Set('python_pycln_options', '')
+call ale#Set('python_pycln_use_global', get(g:, 'ale_use_global_executables', 0))
+call ale#Set('python_pycln_change_directory', 1)
+call ale#Set('python_pycln_auto_pipenv', 0)
+call ale#Set('python_pycln_auto_poetry', 0)
+call ale#Set('python_pycln_config_file', '')
+
+function! ale#fixers#pycln#GetCwd(buffer) abort
+    if ale#Var(a:buffer, 'python_pycln_change_directory')
+        " Run from project root if found, else from buffer dir.
+        let l:project_root = ale#python#FindProjectRoot(a:buffer)
+
+        return !empty(l:project_root) ? l:project_root : '%s:h'
+    endif
+
+    return '%s:h'
+endfunction
+
+function! ale#fixers#pycln#GetExecutable(buffer) abort
+    if (ale#Var(a:buffer, 'python_auto_pipenv') || ale#Var(a:buffer, 'python_pycln_auto_pipenv'))
+    \ && ale#python#PipenvPresent(a:buffer)
+        return 'pipenv'
+    endif
+
+    if (ale#Var(a:buffer, 'python_auto_poetry') || ale#Var(a:buffer, 'python_pycln_auto_poetry'))
+    \ && ale#python#PoetryPresent(a:buffer)
+        return 'poetry'
+    endif
+
+    return ale#python#FindExecutable(a:buffer, 'python_pycln', ['pycln'])
+endfunction
+
+function! ale#fixers#pycln#GetCommand(buffer) abort
+    let l:executable = ale#fixers#pycln#GetExecutable(a:buffer)
+    let l:exec_args = l:executable =~? 'pipenv\|poetry$'
+    \   ? ' run pycln'
+    \   : ''
+
+    return ale#Escape(l:executable) . l:exec_args
+endfunction
+
+function! ale#fixers#pycln#FixForVersion(buffer, version) abort
+    let l:executable = ale#fixers#pycln#GetExecutable(a:buffer)
+    let l:cmd = [ale#Escape(l:executable)]
+
+    if l:executable =~? 'pipenv\|poetry$'
+        call extend(l:cmd, ['run', 'pycln'])
+    endif
+
+    let l:options = ale#Var(a:buffer, 'python_pycln_options')
+
+    if !empty(l:options)
+        call add(l:cmd, l:options)
+    endif
+
+    let l:config_file = ale#Var(a:buffer, 'python_pycln_config_file')
+    let l:config_file = l:options !~# '\v(^| )--config ' && !empty(l:config_file)
+    \   ? ale#Escape(ale#path#Simplify(l:config_file))
+    \   : ''
+
+    if !empty(l:config_file)
+        call add(l:cmd, '--config ' . l:config_file)
+    endif
+
+    call add(l:cmd, '--silence')
+
+    " NOTE: pycln version `1.3.0` support reading from stdin
+    call add(l:cmd, ale#semver#GTE(a:version, [1, 3, 0]) ? '-' : '%s')
+
+    return {
+    \   'cwd': ale#fixers#pycln#GetCwd(a:buffer),
+    \   'command': join(l:cmd, ' '),
+    \}
+endfunction
+
+function! ale#fixers#pycln#Fix(buffer) abort
+    let l:executable = ale#fixers#pycln#GetExecutable(a:buffer)
+    let l:command = ale#fixers#pycln#GetCommand(a:buffer) . ale#Pad('--version')
+
+    return ale#semver#RunWithVersionCheck(
+    \     a:buffer,
+    \     l:executable,
+    \     l:command,
+    \     function('ale#fixers#pycln#FixForVersion'),
+    \)
+endfunction

sources_non_forked/ale/autoload/ale/fixers/ruff.vim

@@ -1,6 +1,13 @@
 " Author: Yining <zhang.yining@gmail.com>
 " Description: ruff as ALE fixer for python files
 
+call ale#Set('python_ruff_executable', 'ruff')
+call ale#Set('python_ruff_options', '')
+call ale#Set('python_ruff_use_global', get(g:, 'ale_use_global_executables', 0))
+call ale#Set('python_ruff_change_directory', 1)
+call ale#Set('python_ruff_auto_pipenv', 0)
+call ale#Set('python_ruff_auto_poetry', 0)
+
 function! ale#fixers#ruff#GetCwd(buffer) abort
     if ale#Var(a:buffer, 'python_ruff_change_directory')
         " Run from project root if found, else from buffer dir.
@@ -9,7 +16,7 @@ function! ale#fixers#ruff#GetCwd(buffer) abort
         return !empty(l:project_root) ? l:project_root : '%s:h'
     endif
 
-    return ''
+    return '%s:h'
 endfunction
 
 function! ale#fixers#ruff#GetExecutable(buffer) abort
@@ -26,29 +33,57 @@ function! ale#fixers#ruff#GetExecutable(buffer) abort
     return ale#python#FindExecutable(a:buffer, 'python_ruff', ['ruff'])
 endfunction
 
-function! ale#fixers#ruff#GetCommand(buffer, version) abort
-    let l:executable = ale_linters#python#ruff#GetExecutable(a:buffer)
+function! ale#fixers#ruff#GetCommand(buffer) abort
+    let l:executable = ale#fixers#ruff#GetExecutable(a:buffer)
     let l:exec_args = l:executable =~? 'pipenv\|poetry$'
     \   ? ' run ruff'
     \   : ''
 
-    " NOTE: ruff version `0.0.72` implement `--fix` with stdin
     return ale#Escape(l:executable) . l:exec_args
-    \   . ale#Pad(ale#Var(a:buffer, 'python_ruff_options'))
-    \   . ' --fix'
-    \   .  (ale#semver#GTE(a:version, [0, 0, 72]) ? ' -' : ' %s')
+endfunction
+
+function! ale#fixers#ruff#FixForVersion(buffer, version) abort
+    let l:executable = ale#fixers#ruff#GetExecutable(a:buffer)
+    let l:cmd = [ale#Escape(l:executable)]
+
+    if l:executable =~? 'pipenv\|poetry$'
+        call extend(l:cmd, ['run', 'ruff'])
+    endif
+
+    let l:options = ale#Var(a:buffer, 'python_ruff_options')
+
+    if !empty(l:options)
+        call add(l:cmd, l:options)
+    endif
+
+    " when --stdin-filename present, ruff will use it for proj root resolution
+    " https://github.com/charliermarsh/ruff/pull/1281
+    let l:fname = expand('#' . a:buffer . '...')
+    call add(l:cmd, '--stdin-filename '.ale#Escape(ale#path#Simplify(l:fname)))
+
+    call add(l:cmd, '--fix')
+
+    " NOTE: ruff version `0.0.72` implements `--fix` with stdin
+    if ale#semver#GTE(a:version, [0, 0, 72])
+        call add(l:cmd, '-')
+    else
+        call add(l:cmd, '%s')
+    endif
+
+    return {
+    \   'cwd': ale#fixers#ruff#GetCwd(a:buffer),
+    \   'command': join(l:cmd, ' '),
+    \}
 endfunction
 
 function! ale#fixers#ruff#Fix(buffer) abort
-    let l:fix_cmd = {buffer -> ale#semver#RunWithVersionCheck(
-    \     buffer,
-    \     ale#fixers#ruff#GetExecutable(buffer),
-    \     '%e --version',
-    \     function('ale#fixers#ruff#GetCommand'),
-    \ )}(a:buffer)
+    let l:executable = ale#fixers#ruff#GetExecutable(a:buffer)
+    let l:command = ale#fixers#ruff#GetCommand(a:buffer) . ale#Pad('--version')
 
-    return {
-    \ 'cwd': ale#fixers#ruff#GetCwd(a:buffer),
-    \ 'command': l:fix_cmd,
-    \}
+    return ale#semver#RunWithVersionCheck(
+    \     a:buffer,
+    \     l:executable,
+    \     l:command,
+    \     function('ale#fixers#ruff#FixForVersion'),
+    \)
 endfunction

sources_non_forked/ale/autoload/ale/fixers/rustywind.vim

@@ -0,0 +1,17 @@
+scriptencoding utf-8
+" Author: Guillermo Roig <groig@protonmail.com>
+" Description: Sort TailwindCSS classes with rustywind
+
+call ale#Set('html_rustywind_executable', 'rustywind')
+call ale#Set('html_rustywind_options', '')
+
+function! ale#fixers#rustywind#Fix(buffer) abort
+    let l:executable = ale#Var(a:buffer, 'html_rustywind_executable')
+    let l:options = ale#Var(a:buffer, 'html_rustywind_options')
+
+    return {
+    \   'command': ale#Escape(l:executable)
+    \       . (empty(l:options) ? '' : ' ' . l:options)
+    \       . ' --stdin'
+    \}
+endfunction