Add support with Go language.

sources_non_forked/vim-go/indent/go.vim

@@ -0,0 +1,86 @@
+" Copyright 2011 The Go Authors. All rights reserved.
+" Use of this source code is governed by a BSD-style
+" license that can be found in the LICENSE file.
+"
+" indent/go.vim: Vim indent file for Go.
+"
+" TODO:
+" - function invocations split across lines
+" - general line splits (line ends in an operator)
+
+if exists("b:did_indent")
+  finish
+endif
+let b:did_indent = 1
+
+" C indentation is too far off useful, mainly due to Go's := operator.
+" Let's just define our own.
+setlocal nolisp
+setlocal autoindent
+setlocal indentexpr=GoIndent(v:lnum)
+setlocal indentkeys+=<:>,0=},0=)
+
+if exists("*GoIndent")
+  finish
+endif
+
+" don't spam the user when Vim is started in Vi compatibility mode
+let s:cpo_save = &cpo
+set cpo&vim
+
+function! GoIndent(lnum) abort
+  let prevlnum = prevnonblank(a:lnum-1)
+  if prevlnum == 0
+    " top of file
+    return 0
+  endif
+
+  " grab the previous and current line, stripping comments.
+  let prevl = substitute(getline(prevlnum), '//.*$', '', '')
+  let thisl = substitute(getline(a:lnum), '//.*$', '', '')
+  let previ = indent(prevlnum)
+
+  let ind = previ
+
+  for synid in synstack(a:lnum, 1)
+    if synIDattr(synid, 'name') == 'goRawString'
+      if prevl =~ '\%(\%(:\?=\)\|(\|,\)\s*`[^`]*$'
+        " previous line started a multi-line raw string
+        return 0
+      endif
+      " return -1 to keep the current indent.
+      return -1
+    endif
+  endfor
+
+  if prevl =~ '[({]\s*$'
+    " previous line opened a block
+    let ind += shiftwidth()
+  endif
+  if prevl =~# '^\s*\(case .*\|default\):$'
+    " previous line is part of a switch statement
+    let ind += shiftwidth()
+  endif
+  " TODO: handle if the previous line is a label.
+
+  if thisl =~ '^\s*[)}]'
+    " this line closed a block
+    let ind -= shiftwidth()
+  endif
+
+  " Colons are tricky.
+  " We want to outdent if it's part of a switch ("case foo:" or "default:").
+  " We ignore trying to deal with jump labels because (a) they're rare, and
+  " (b) they're hard to disambiguate from a composite literal key.
+  if thisl =~# '^\s*\(case .*\|default\):$'
+    let ind -= shiftwidth()
+  endif
+
+  return ind
+endfunction
+
+" restore Vi compatibility settings
+let &cpo = s:cpo_save
+unlet s:cpo_save
+
+" vim: sw=2 ts=2 et

sources_non_forked/vim-go/indent/gohtmltmpl.vim

@@ -0,0 +1,54 @@
+if exists("b:did_indent")
+  finish
+endif
+
+runtime! indent/html.vim
+
+" Indent Golang HTML templates
+setlocal indentexpr=GetGoHTMLTmplIndent(v:lnum)
+setlocal indentkeys+==else,=end
+
+" Only define the function once.
+if exists("*GetGoHTMLTmplIndent")
+  finish
+endif
+
+" don't spam the user when Vim is started in Vi compatibility mode
+let s:cpo_save = &cpo
+set cpo&vim
+
+function! GetGoHTMLTmplIndent(lnum)
+  " Get HTML indent
+  if exists('*HtmlIndent')
+    let ind = HtmlIndent()
+  else
+    let ind = HtmlIndentGet(a:lnum)
+  endif
+
+  " The value of a single shift-width
+  if exists('*shiftwidth')
+    let sw = shiftwidth()
+  else
+    let sw = &sw
+  endif
+
+  " If need to indent based on last line
+  let last_line = getline(a:lnum-1)
+  if last_line =~ '^\s*{{-\=\s*\%(if\|else\|range\|with\|define\|block\).*}}'
+    let ind += sw
+  endif
+
+  " End of FuncMap block
+  let current_line = getline(a:lnum)
+  if current_line =~ '^\s*{{-\=\s*\%(else\|end\).*}}'
+    let ind -= sw
+  endif
+
+  return ind
+endfunction
+
+" restore Vi compatibility settings
+let &cpo = s:cpo_save
+unlet s:cpo_save
+
+" vim: sw=2 ts=2 et